indexing
	description: "Build result message."
	author: "Patrick Ruckstuhl <patrick@tario.org>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_BUILD_RESULT_MESSAGE

inherit
	O_BUILD_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_result: like compilation_result) is
			-- Create with a compilation result.
		do
			make_message
			compilation_result := a_result
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		do
			Precursor (a_msg)
			compilation_result := a_msg.arguments.item (result_argument).to_boolean
		end

feature -- Access

	type: STRING is
			-- Type of the message.
		once
			Result := build_result_type
		end

	compilation_result: BOOLEAN
			-- Result of the compilatino

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			create Result.make (1)
			Result.force (compilation_result.out, result_argument)
		end

feature {NONE} -- Implementation

	result_argument: STRING is "result"

end