indexing
	description: "Community retrieve wiki page message."
	author: "Marco Zietzling <marco.zietzling@gmail.com>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_COMMUNITY_RETRIEVE_WIKI_PAGE_MESSAGE

inherit
	O_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments
		end

	O_COMMUNITY_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_community_name: like community_name; a_wiki_title: like wiki_title) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_community_name_ok: a_community_name /= Void and then not a_community_name.is_empty
			a_wiki_title_ok: a_wiki_title /= Void and then not a_wiki_title.is_empty
		do
			make_session (a_session)
			community_name := a_community_name
			wiki_title := a_wiki_title
		ensure
			community_name_set: community_name = a_community_name
			wiki_title_set: wiki_title = a_wiki_title
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			community_name := l_args.item (community_name_argument)
			wiki_title := l_args.item (wiki_title_argument)
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := community_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := community_retrieve_wiki_page_type
		end

	community_name: STRING
			-- Community name.

	wiki_title: STRING
			-- Wiki title.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (community_name, community_name_argument)
			Result.force (wiki_title, wiki_title_argument)
		end

feature {NONE} -- Implementation

	community_name_argument: STRING is "community_name"
	wiki_title_argument: STRING is "wiki_title"

invariant
	community_name_ok: community_name /= Void and then not community_name.is_empty
	wiki_title_ok: wiki_title /= Void and then not wiki_title.is_empty
end