indexing
	description: "Message that contains a single string"
	author: "Rafael Bischof <bischora@student.ethz.ch>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_GENERAL_STRING_MESSAGE

inherit
	O_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

	O_GENERAL_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_string: like string) is
			-- Create.
		require
			a_string_not_void: a_string /= Void
		do
			make_message
			string := a_string
		ensure
			string_set: string = a_string
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			string := l_args.item ("string")
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := general_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := general_string_type
		end

	string: STRING
			-- string of this message

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			create Result.make (1)
			Result.force (string, "string")
		end

invariant
	string_not_void: string /= Void
end