indexing
	description: "Issue list reply message."
	author: "Peter Wyss <wyssp@ethz.ch>"
	date: "$Date: 2007-08-02 10:48:11 +0200 (Thu, 02 Aug 2007) $"
	revision: "$Revision: 627 $"

class
	O_ISSUE_LIST_REPLY_MESSAGE

inherit
	O_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

	O_ISSUE_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_issue_list: like issue_list) is
			-- Create.
		require
			a_issue_list_not_void: a_issue_list /= Void
		do
			make_message
			issue_list := a_issue_list
		ensure
			issue_list_set: issue_list = a_issue_list
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
			l_item: TUPLE [INTEGER, INTEGER, INTEGER, STRING, STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			create issue_list.make (l_args.count)
			from
				l_args.start
			until
				l_args.after
			loop
				l_item ?= deserialize(l_args.item_for_iteration)
				issue_list.force (l_item, l_args.key_for_iteration.to_integer)
				l_args.forth
			end
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := issue_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := issue_list_reply_type
		end

	issue_list: DS_HASH_TABLE [TUPLE [issue_id: INTEGER; creation_time: INTEGER; last_modified: INTEGER; user: STRING; title: STRING; tags: STRING], INTEGER]
			-- issue list.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			create Result.make (issue_list.count)
			from
				issue_list.start
			until
				issue_list.after
			loop
				Result.force (serialize(issue_list.item_for_iteration), issue_list.key_for_iteration.out)
				issue_list.forth
			end
		end

invariant
	issue_list_not_void: issue_list /= Void
end