indexing
	description: "Issue retrieve message."
	author: "Peter Wyss <wyssp@ethz.ch>"
	date: "$Date: 2007-07-08 11:41:12 +0200 (Sun, 08 Jul 2007) $"
	revision: "$Revision: 452 $"

class
	O_ISSUE_RETRIEVE_MESSAGE

inherit
	O_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments
		end

	O_ISSUE_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_issue_id: like issue_id; a_project: like project) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_issue_id_ok: a_issue_id > 0
			a_project_ok: a_project > 0
		do
			make_session (a_session)
			issue_id := a_issue_id
			project := a_project
		ensure
			issue_id_set: issue_id = a_issue_id
			project_set: project = a_project
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			issue_id := l_args.item (issue_id_argument).to_integer
			project := l_args.item (project_argument).to_integer
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := issue_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := issue_retrieve_type
		end

	issue_id: INTEGER
			-- Issue id

	project: INTEGER
			-- Project id

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (issue_id.out, issue_id_argument)
			Result.force (project.out, project_argument)
		end

feature {NONE} -- Implementation

	issue_id_argument: STRING is "issue_id"
	project_argument: STRING is "project"

invariant
	issue_id_ok: issue_id > 0
	project_ok: project > 0
end