indexing
	description: "Project list all message."
	author: "Patrick Ruckstuhl <patrick@tario.org>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_PROJECT_LIST_ALL_MESSAGE

inherit
	O_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments
		end

	O_PROJECT_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_show_hidden: like show_hidden) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
		do
			make_session (a_session)
			show_hidden := a_show_hidden
		ensure
			show_hidden_set: show_hidden = a_show_hidden
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			show_hidden := l_args.item (show_hidden_argument).to_boolean
		end

feature -- Access

	namespace: STRING_8 is
			-- Namespace of the message type.
		once
			Result := project_namespace
		end

	type: STRING_8 is
			-- Type of the message.
		once
			Result := project_list_all_type
		end

	show_hidden: BOOLEAN
			-- Show all projects including hidden projects?

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (show_hidden.out, show_hidden_argument)
		end

feature {NONE} -- Implementation

	show_hidden_argument: STRING is "show_hidden"

end