indexing
	description: "Project list communities message."
	author: "Marco Zietzling <marco.zietzling@gmail.com>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_PROJECT_LIST_COMMUNITIES_MESSAGE

inherit
	O_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments
		end

	O_PROJECT_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_project_id: like project_id) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_project_id_ok: a_project_id > 0
		do
			make_session (a_session)
			project_id := a_project_id
		ensure
			project_id_set: project_id = a_project_id
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			project_id := l_args.item (project_id_argument).to_integer
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := project_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := project_list_communities_type
		end

	project_id: INTEGER
			-- Project ID

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (project_id.out, project_id_argument)
		end

feature {NONE} -- Implementation

	project_id_argument: STRING is "project_id"

invariant
	project_id_ok: project_id > 0
end