indexing
	description: "Project list partial message."
	author: "Dennis Rietmann <dennis.rietmann@gmail.com>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_PROJECT_LIST_PARTIAL_MESSAGE

inherit
	O_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments
		end

	O_PROJECT_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_show_hidden: like show_hidden; a_start_index: like start_index; a_count: like count) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_start_index_ok: a_start_index > -1
			a_count_ok: a_count > 0
		do
			make_session (a_session)
			show_hidden := a_show_hidden
			start_index := a_start_index
			count := a_count
		ensure
			show_hidden_set: show_hidden = a_show_hidden
			start_index_set: start_index = a_start_index
			count_set: count = a_count
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			show_hidden := l_args.item (show_hidden_argument).to_boolean
			start_index := l_args.item (start_index_argument).to_integer
			count := l_args.item (count_argument).to_integer
		end

feature -- Access

	namespace: STRING_8 is
			-- Namespace of the message type.
		once
			Result := project_namespace
		end

	type: STRING_8 is
			-- Type of the message.
		once
			Result := project_list_partial_type
		end


	show_hidden: BOOLEAN
			-- Show all projects including hidden projects?

	start_index: INTEGER
			-- the start index into the project list

	count: INTEGER
			-- The number of projects to be returned (starting at 'count')

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (show_hidden.out, show_hidden_argument)
			Result.force (start_index.out, start_index_argument)
			Result.force (count.out, count_argument)
		end

feature {NONE} -- Implementation

	show_hidden_argument: STRING is "show_hidden"
	start_index_argument: STRING is "start_index"
	count_argument: STRING is "count"

end