indexing
	description: "Project message."
	author: "Peter Wyss <wyssp@ethz.ch>"
	date: "$Date: 2007-05-12 19:57:51 +0200 (Sat, 12 May 2007) $"
	revision: "$Revision: 257 $"

class
	O_PROJECT_REQUEST_RETRIEVE_MESSAGE

inherit
	O_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments
		end

	O_PROJECT_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_request_project_name: like request_project_name) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_request_project_name_ok: a_request_project_name /= Void and then not a_request_project_name.is_empty
		do
			make_session (a_session)
			request_project_name := a_request_project_name
		ensure
			request_project_name_set: request_project_name = a_request_project_name
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			request_project_name := l_args.item (request_project_name_argument)
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := project_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := project_request_retrieve_type
		end

	request_project_name: STRING
			-- Request project name

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (request_project_name.out, request_project_name_argument)
		end

feature {NONE} -- Implementation

	request_project_name_argument: STRING is "request_project_name"

invariant
	request_project_name_ok: request_project_name /= Void

end