indexing
	description: "Release retrieve internal message."
	author: "Peter Wyss <wyssp@ethz.ch>"
	date: "$Date: 2007-07-08 11:41:12 +0200 (Sun, 08 Jul 2007) $"
	revision: "$Revision: 452 $"

class
	O_RELEASE_RETRIEVE_INTERNAL_MESSAGE

inherit
	O_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

	O_RELEASE_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_release_id: like release_id) is
			-- Create.
		require
			a_release_id_ok: a_release_id > 0
		do
			make_message
			release_id := a_release_id
		ensure
			release_id_set: release_id = a_release_id
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			release_id := l_args.item (release_id_argument).to_integer
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := release_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := release_retrieve_internal_type
		end

	release_id: INTEGER
			-- Release id


	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			create Result.make (1)
			Result.force (release_id.out, release_id_argument)
		end

feature {NONE} -- Implementation

	release_id_argument: STRING is "release_id"

invariant
	release_id_ok: release_id > 0
end