indexing
	description: "Add FOAF message. "
	author: "Ueli Weiss"
	date: "$Date: 2007-10-23 15:46:06 +0200 (Tue, 23 Oct 2007) $"
	revision: "$Revision: 1129 $"

class
	O_USER_ADD_FOAF_MESSAGE

inherit
	O_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments
		end

	O_USER_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_foaf: like foaf) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_foaf_ok: a_foaf /= Void and then not a_foaf.is_empty
		do
			make_session (a_session)
			foaf := a_foaf
		ensure
			foaf_set: foaf = a_foaf
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			foaf := l_args.item (foaf_argument)
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := user_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := user_add_foaf_type
		end

	foaf: STRING
			-- foaf.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (foaf, foaf_argument)
		end

feature {NONE} -- Implementation

	foaf_argument: STRING is "foaf"

invariant
	foaf_ok: foaf /= Void and then not foaf.is_empty

end