indexing
	description: "User set profile visibility"
	author: "Ueli Weiss"
	date: "$Date: 2007-10-23 15:46:06 +0200 (Tue, 23 Oct 2007) $"
	revision: "$Revision: 1129 $"

class
	O_USER_CHANGE_PROFILE_VISIBLE_MESSAGE

inherit
	O_USER_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments,
			type
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_value: like value) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_value_ok: a_value >= 0
		do
			make_session (a_session)
			value := a_value
		ensure
			value_set: value = a_value
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			value := l_args.item (value_argument).to_integer
		end

feature -- Access

	type: STRING is
			-- Type of the message.
		once
			Result := user_change_profile_visible_type
		end

	value: INTEGER
			-- profile visibility encoded into an INTEGER.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (value.out, value_argument)
		end

feature {NONE} -- Implementation

	value_argument: STRING is "value"

invariant
	value_ok: value >= 0

end