indexing
	description: "Reply to a user key request."
	author: "Patrick Ruckstuhl <patrick@tario.org>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_USER_KEY_REPLY_MESSAGE

inherit
	O_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

	O_USER_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_key: like key) is
			-- Create.
		require
			a_key_ok: a_key /= Void and then not a_key.is_empty
		do
			make_message
			key := a_key
		ensure
			key_set: key = a_key
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			key := l_args.item (key_argument)
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := user_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := user_key_reply_type
		end

	key: STRING
			-- Key of the user

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			create Result.make (1)
			Result.force (key, key_argument)
		end

feature {NONE} -- Implementation

	key_argument: STRING is "key"

invariant
	key_ok: key /= Void and then not key.is_empty

end