indexing
	description: "User list communities message."
	author: "Marco Zietzling <marco.zietzling@gmail.com>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_USER_LIST_COMMUNITIES_MESSAGE

inherit
	O_USER_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments,
			type
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_username: like username) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_username_ok: a_username /= Void and then not a_username.is_empty
		do
			make_session (a_session)
			username := a_username
		ensure
			username_set: username = a_username
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			username := l_args.item (username_argument)
		end

feature -- Access

	type: STRING is
			-- Type of the message.
		once
			Result := user_list_communities_type
		end

	username: STRING
			-- Username to list communities for.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (username, username_argument)
		end

feature {NONE} -- Implementation

	username_argument: STRING is "username"

invariant
	username_ok: username /= Void and then not username.is_empty
end