indexing
	description: "User list message."
	author: "Patrick Ruckstuhl <patrick@tario.org>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_USER_LIST_MESSAGE

inherit
	O_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

	O_USER_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_user_list: like user_list) is
			-- Create.
		require
			a_user_list_not_void: a_user_list /= Void
		do
			make_message
			user_list := a_user_list
		ensure
			user_list_set: user_list = a_user_list
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			create user_list.make (l_args.count)
			from
				l_args.start
			until
				l_args.after
			loop
				user_list.force (l_args.item_for_iteration, l_args.key_for_iteration.to_integer)
				l_args.forth
			end
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := user_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := user_list_type
		end

	user_list: HASH_TABLE [STRING, INTEGER]
			-- Project list.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			create Result.make (user_list.count)
			from
				user_list.start
			until
				user_list.after
			loop
				Result.force (user_list.item_for_iteration, user_list.key_for_iteration.out)
				user_list.forth
			end
		end

invariant
	user_list_not_void: user_list /= Void
end