indexing
	description: "User remove bookmark."
	author: "Peter Wyss <wyssp@ethz.ch>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_USER_REMOVE_BOOKMARK_MESSAGE

inherit
	O_USER_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments,
			type
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_project: like project) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_project_ok: a_project > 0
		do
			make_session (a_session)
			project := a_project
		ensure
			project_set: project = a_project
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			project := l_args.item (project_argument).to_integer
		end

feature -- Access

	type: STRING is
			-- Type of the message.
		once
			Result := user_remove_bookmark_type
		end

	project: INTEGER
			-- Project id

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (project.out, project_argument)
		end

feature {NONE} -- Implementation

	project_argument: STRING is "project"

invariant
	project_ok: project > 0
end