indexing
	description: "Remove Openid Message. "
	author: "Ueli Weiss"
	date: "$Date: 2007-10-23 15:46:06 +0200 (Tue, 23 Oct 2007) $"
	revision: "$Revision: 1129 $"

class
	O_USER_REMOVE_OPENID_MESSAGE

inherit
	O_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments
		end

	O_USER_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_openid: like openid) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_openid_ok: a_openid /= Void and then not a_openid.is_empty
		do
			make_session (a_session)
			openid := a_openid
		ensure
			openid_set: openid = a_openid
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			openid := l_args.item (openid_argument)
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := user_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := user_remove_openid_type
		end

	openid: STRING
			-- openid.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (openid, openid_argument)
		end

feature {NONE} -- Implementation

	openid_argument: STRING is "openid"

invariant
	openid_ok: openid /= Void and then not openid.is_empty

end