indexing
	description: "User request friendship message."
	author: "Marco Zietzling <marco.zietzling@gmail.com>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_USER_REQUEST_FRIENDSHIP_MESSAGE

inherit
	O_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments
		end

	O_USER_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; a_requestee: like requestee) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			a_requestee_ok: a_requestee /= Void and then not a_requestee.is_empty
		do
			make_session (a_session)
			requestee := a_requestee
		ensure
			requestee_set: requestee = a_requestee
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			requestee := l_args.item (requestee_argument)
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := user_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := user_request_friendship_type
		end

	requestee: STRING
			-- Requestee.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (requestee.out, requestee_argument)
		end

feature {NONE} -- Implementation

	requestee_argument: STRING is "requestee"

invariant
	requestee_ok: requestee /= Void and then not requestee.is_empty
end