indexing
	description: "User reset password reply message."
	author: "Peter Wyss <wyssp@ethz.ch>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_USER_RESET_PASSWORD_REPLY_MESSAGE

inherit
	O_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

	O_USER_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_password: like password; a_email: like email) is
			-- Create.
		require
			a_password_ok: a_password /= Void and then not a_password.is_empty
			a_email_ok: a_email /= Void and then not a_email.is_empty
		do
			make_message
			password := a_password
			email := a_email
		ensure
			password_set: password = a_password
			email_set: email = a_email
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			password := l_args.item (password_argument)
			email := l_args.item (email_argument)
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := user_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := user_reset_password_reply_type
		end

	password: STRING
			-- Password of the user

	email: STRING
			-- Email of the user

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			create Result.make (2)
			Result.force (password, password_argument)
			Result.force (email, email_argument)
		end

feature {NONE} -- Implementation

	password_argument: STRING is "password"
	email_argument: STRING is "email"

invariant
	password_ok: password /= Void and then not password.is_empty
	email_ok: email /= Void and then not email.is_empty
end