indexing
	description: "Retrieve user from email message."
	author: "Ueli Weiss"
	date: "$Date: 2007-10-23 15:46:06 +0200 (Tue, 23 Oct 2007) $"
	revision: "$Revision: 1129 $"

class
	O_USER_RETRIEVE_USER_FROM_EMAIL_MESSAGE

inherit
	O_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

	O_USER_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_email: like email) is
			-- Create.
		require
			a_email_ok: a_email /= Void and then not a_email.is_empty
		do
			make_message
			email := a_email
		ensure
			email_set: email = a_email
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			email := l_args.item (email_argument)
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := user_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := user_retrieve_user_from_email_type
		end

	email: STRING
			-- Name of the user

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			create Result.make (1)
			Result.force (email, email_argument)
		end

feature {NONE} -- Implementation

	email_argument: STRING is "email"

invariant
	email_ok: email /= Void and then not email.is_empty

end