indexing
	description: "User set icon message"
	author: "Marco Zietzling <marco.zietzling@gmail.com>"
	date: "$Date$"
	revision: "$Revision$"

class
	O_USER_SET_ICON_MESSAGE

inherit
	O_USER_SESSION_MESSAGE
		rename
			make as make_session
		redefine
			make_from_generic,
			arguments,
			type
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_session: like session; an_icon: like icon) is
			-- Create.
		require
			a_session_ok: a_session /= Void and then not a_session.is_empty
			an_icon_ok: an_icon /= Void and then not an_icon.is_empty
		do
			make_session (a_session)
			icon := an_icon
		ensure
			icon_set: icon = an_icon
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			icon := l_args.item (icon_argument)
		end

feature -- Access

	type: STRING is
			-- Type of the message.
		once
			Result := user_set_icon_type
		end

	icon: STRING
			-- Filename of new user icon.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			Result := Precursor
			Result.force (icon, icon_argument)
		end

feature {NONE} -- Implementation

	icon_argument: STRING is "icon"

invariant
	icon_ok: icon /= Void and then not icon.is_empty
end