indexing
	description: "reply from requesting the list of openids associated with a given username. "
	author: "Ueli Weiss"
	date: "$Date$"
	revision: "$Revision$"

class
	O_USER_STRINGARRAY_REPLY_MESSAGE

inherit
	O_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

	O_USER_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_content: like content) is
			-- Create.
		require
			a_content_not_void: a_content /= Void
		do
			make_message
			content := a_content
		ensure
			content_set: content = a_content
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			create content.make (0, l_args.count-1)
			from
				l_args.start
			until
				l_args.after
			loop
				content.put (l_args.item_for_iteration, l_args.key_for_iteration.to_integer)
				l_args.forth
			end
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := user_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := user_stringarray_reply_type
		end

	content: ARRAY [STRING]
			-- Array of Openids.

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		local
			i: INTEGER
		do
			create Result.make (content.count)
			from
				i := 0
			until
				i >= content.count
			loop
				Result.force (content.item(i), i.out)
				i := i + 1
			end
		end

invariant
	centent_not_void: content /= Void

end