indexing
	description: "Workitem mail message."
	author: "Peter Wyss <wyssp@ethz.ch>"
	date: "$Date: 2007-07-08 11:41:12 +0200 (Sun, 08 Jul 2007) $"
	revision: "$Revision: 452 $"

class
	O_WORKITEM_MAIL_MESSAGE

inherit
	O_MESSAGE
		rename
			make as make_message
		redefine
			make_from_generic
		end

	O_WORKITEM_CONSTANTS
		undefine
			out
		end

create
	make

create {O_MESSAGE_FACTORY}
	make_from_generic

feature {NONE} -- Initialization

	make (a_workitem_id: like workitem_id) is
			-- Create.
		require
			a_workitem_id_ok: a_workitem_id > 0
		do
			make_message
			workitem_id := a_workitem_id
		ensure
			workitem_id_set: workitem_id = a_workitem_id
		end

	make_from_generic (a_msg: O_GENERIC_MESSAGE) is
			-- Create from a generic message.
		local
			l_args: HASH_TABLE [STRING, STRING]
		do
			Precursor (a_msg)
			l_args := a_msg.arguments
			workitem_id := l_args.item (workitem_id_argument).to_integer
		end

feature -- Access

	namespace: STRING is
			-- Namespace of the message type.
		once
			Result := workitem_namespace
		end

	type: STRING is
			-- Type of the message.
		once
			Result := workitem_mail_type
		end

	workitem_id: INTEGER
			-- Workitem id

	arguments: HASH_TABLE [STRING, STRING] is
			-- Named arguments.
		do
			create Result.make (1)
			Result.force (workitem_id.out, workitem_id_argument)
		end

feature {NONE} -- Implementation

	workitem_id_argument: STRING is "workitem_id"

invariant
	workitem_id_ok: workitem_id > 0
end