indexing
	description: "API interface to build services."
	author: "Patrick Ruckstuhl <patrick@tario.org>"
	date: "$Date$"
	revision: "$Revision$"

class
	BUILD_SERVICE

inherit
	API_SERVICE

create
	make

feature -- Basic operations

	simple (a_auth: STRING): BOOLEAN_REF is
			-- Launch a simple build, authenticate with a_auth, return true on successful build.
		local
			l_msg: O_BUILD_SIMPLE_MESSAGE
			l_build_rep: O_BUILD_RESULT_MESSAGE
		do
				-- generate api message
			create l_msg.make

				-- wait for status reply or timeout (10 min) and return the corresponding result
			send_and_wait_for_reply (l_msg)
			if not is_timeout then
				l_build_rep ?= last_reply
				check
					build_result: l_build_rep /= Void
				end
				create Result
				Result.set_item (l_build_rep.compilation_result)
			else
				create Result
				Result.set_item (False)
			end
		end

feature -- Creation

	new_tuple (a_name: STRING): TUPLE is
			-- Tuple of default-valued arguments to pass to call `a_name'.
		do
			if a_name.is_equal (Simple_name) then
				create {TUPLE [STRING]}Result
			end
		end

feature -- Initialisation

	self_register is
			-- Register all actions for this service
		do
			register (agent simple, Simple_name)
		end

feature {NONE} -- Implementation

	Simple_name: STRING is "simple"
			-- Name of `simple' service

end