indexing

	description: "[

		Implements the main scene of mixer.
		
		Use this class to start the scene.
		
		Note: This class sets the position of all the channels and of the master.

	]"
	date: "$Date$"
	revision: "$Revision$"

class MIXER_SCENE

inherit

	MIXER_CONSTANTS
		export {NONE} all end

	EM_WIDGET_SCENE
		export {NONE} all end

	EM_AUDIO_CONSTANTS
		export {NONE} all end

	EM_SHARED_BITMAP_FACTORY
		export {NONE} all end

	EM_SHARED_SUBSYSTEMS
		export {NONE} all end

create

	make

feature {NONE} -- Initialization

	make is
			-- Create scene.
		local
			i: INTEGER
			channel: MIXER_CHANNEL
		do
			make_widget_scene
			set_background (create {EM_BITMAP_BACKGROUND}.make_from_file (image_directory + "/mixer.png"))
			audio_subsystem.mixer.open (44100, Em_audio_format_s16sys, Em_stereo, Em_default_chunk_size)
			audio_subsystem.mixer.channels.extend (6)

			create master.make
			master.set_position (901, 0)
			master.set_dimension (120, 768)
			master.set_transparent
			add_widget (master)
			create music_channel.make (master)
			music_channel.set_position (0, 215)
			music_channel.set_dimension (240, 553)
			music_channel.set_transparent
			add_widget (music_channel)
			master.set_music_channel (music_channel)
			create channels.make (1, 6)
			from
				i := 1
			until
				i > 6
			loop
				create channel.make_with_identifier (i, master)
				channel.set_position (244 + (i - 1) * 109, 0)
				channel.set_dimension (120, 768)
				channel.set_transparent
				channels.put (channel, i)
				add_widget (channel)
				i := i + 1
			end
			master.set_channels (channels)
			create visualizer.make_positioned (47, 70)
			add_widget (visualizer)
		end

feature -- Access

	visualizer: MIXER_VISUALIZER
		-- Visualizer of mixer

	music_channel: MIXER_MUSIC_CHANNEL
		-- Music channel of mixer

	channels: ARRAY [MIXER_CHANNEL]
		-- Channels of mixer

	master: MIXER_MASTER
		-- Master of mixer

end