indexing

	description: "[

		EiffelMedia WIDGET_BROWSER application.
		Display all available widgets and themes.

	]"
	date: "$Date$"
	revision: "$Revision$"

class WIDGET_BROWSER

inherit

	EM_APPLICATION

	EM_SHARED_THEME
		export {NONE} all end

create

	make

feature {NONE} -- Initialisation

	make (arguments: ARRAY [STRING]) is
			-- Create the main application.
		local
			keyboard: EM_KEYBOARD
		do
			-- Initiliase subsystems
			-- Argument 0 is the executed command. Argument 1 is the first real argument.
			if arguments.count > 1 and then arguments.item (1).is_equal ("noopengl") then
				Video_subsystem.set_opengl (False)
			else
				Video_subsystem.set_opengl (True)
			end
			Video_subsystem.set_video_surface_width (Window_width)
			Video_subsystem.set_video_surface_height (Window_height)
			Video_subsystem.set_video_bpp (Screen_resolution)
			Video_subsystem.set_fullscreen (Fullscreen)
			Video_subsystem.enable

			initialize_screen

			-- Check subsystem initialisation
			if Video_subsystem.is_enabled then

				-- Set global options
				set_application_id ("em_widget_browser")
				set_window_title ("EiffelMedia: Widget Browser")
				set_window_icon ("icon.png")

				create keyboard.make_snapshot
				keyboard.enable_unicode_characters
				keyboard.enable_repeating_key_down_events (200, 100)

				load_eclipse_theme

				-- Set first scene and launch it
				set_scene (create {WIDGET_BROWSER_SCENE}.make)

				launch

				-- Disable subsystems
				Video_subsystem.disable
			else
				io.error.put_string ("Failed to initialise video subsystem.%N")
			end
		end

feature {NONE} -- Implementation

	Window_width: INTEGER is 740
			-- Window width

	Window_height: INTEGER is 700
			-- Window height

	Screen_resolution: INTEGER is 32
			-- Screen resolution

	Fullscreen: BOOLEAN is false
			-- Fullscreen?

end