indexing

	description: "[

		Singleplayer - New Game Menu

	]"
	date: "$Date$"
	revision: "$Revision$"

class BB_SINGLEPLAYER_NEW_GAME

inherit

	BB_MENU

	EM_SHARED_SUBSYSTEMS
		export {NONE} all end

create

	make

feature -- Initialization

	make is
			-- initialize menu
		local
			a_button: BB_MENU_BUTTON
			a_label: EM_LABEL
			file: PLAIN_TEXT_FILE
			custom_level_y: INTEGER
			second_button_name: STRING
		do
			init_menu

			create file.make ("./levels/original.ord")

			if file.exists then
				create a_button.make ("Original Levels")
				a_button.set_position (bb_window_width // 2 - a_button.width // 2, 220)
				a_button.pressed_event.subscribe (agent original_levels_pressed)
				add_button (a_button)

				second_button_name := "Custom Levels"
				custom_level_y := 270
			else
				create a_label.make_from_text ("There are only 4 levels in this version.%NYou can download the full level set at%Nwww.brick-breaker.ch.vu")
				a_label.set_font (standard_ttf_fonts.bitstream_vera_sans (20))
				a_label.enable_multilined
				a_label.align_center
				a_label.set_foreground_color (create {EM_COLOR}.make_white)
				a_label.resize_to_optimal_dimension
				a_label.set_position (bb_window_width // 2 - a_label.width // 2, 220)
				add_widget (a_label)

				second_button_name := "Start Game"
				custom_level_y := 370
			end

			create a_button.make (second_button_name)
			a_button.set_position (bb_window_width // 2 - a_button.width // 2, custom_level_y)
			a_button.pressed_event.subscribe (agent custom_levels_pressed)
			add_button (a_button)

			create a_button.make ("Back")
			a_button.set_position (bb_window_width // 2 - a_button.width // 2, custom_level_y + 100)
			a_button.pressed_event.subscribe (agent back_button_pressed)
			add_button (a_button)

			set_selected_menu_item (1)
		end

feature -- Events

	back_button_pressed is
			-- back button pressed
		do
			set_next_scene (create {BB_SINGLEPLAYER}.make)
			start_next_scene
		end

	original_levels_pressed is
			-- original levels pressed
		do
			bb_settings.set_level_set ("original")
			bb_settings.write_user_settings

			set_next_scene (create {BB_LEVEL_SCENE}.make_from_first_level)
			start_next_scene
		end

	custom_levels_pressed is
			-- custom levels pressed
		do
			bb_settings.set_level_set ("custom")
			bb_settings.write_user_settings

			set_next_scene (create {BB_LEVEL_SCENE}.make_from_first_level)
			start_next_scene
		end

end