indexing

	description: "[

		Container EM_GOOF_XY_VEHICLE for example a ship or tank with turrets

	]"
	date: "$Date$"
	revision: "$Revision$"

class EM_GOOF_XY_TRANSPORT

inherit

	EM_GOOF_XY_VEHICLE
	redefine
		process,
		draw,
		make,
		make_multiple_picture
	end
	EM_GOOF_CONTAINER
	undefine
		process,
		draw,
		make
	end

create

	make, make_multiple_picture, premake

feature -- Initialization

	make(img: EM_BITMAP x: DOUBLE y: DOUBLE phs: EM_GOOF_PHYSICS) is
			-- Make transporter
		do
			Precursor{EM_GOOF_XY_VEHICLE}(img,x,y,phs)
			Precursor{EM_GOOF_CONTAINER}(img,x,y,phs)
		end

	make_multiple_picture(imgs: DS_LINKED_LIST[EM_BITMAP] x: DOUBLE y: DOUBLE phs: EM_GOOF_PHYSICS) is
			-- Make with multiple picture for rotation
		do
			make(imgs.item(1),x,y,phs)
			Precursor{EM_GOOF_XY_VEHICLE}(imgs,x,y,phs)
		end

feature -- Drawing

	draw(screen: EM_VIDEO_SURFACE at: EM_VECTOR_2D at_angle: DOUBLE) is
			-- Draw object at 'at' and rotated with 'at_angle' around 'at'
		do
			Precursor{EM_GOOF_XY_VEHICLE}(screen, at, at_angle)
			Precursor{EM_GOOF_CONTAINER}(screen, at, at_angle+arc)
		end

feature -- Processing

	process(time_length: DOUBLE) is
			-- Process this object
		do
			Precursor{EM_GOOF_XY_VEHICLE}(time_length)
			Precursor{EM_GOOF_CONTAINER}(time_length)
		end

end