indexing

	description: "[

		Event that requests object creation of a certain type from an other party.
		You need to specify the type of the object that you request to be created.
		
		As response of this request an EM_NET_CREATE_OBJECT_RESPONSE might be sent.
		The object will (by default) be requested to be created in the same group as
		the event is sent from.
		
		This event is only a request, no object will actually be created. The receiver must
		decide on the action which follows this request.
		
		This is a secured two phase commit event.

	]"
	date: "$Date$"
	revision: "$Revision$"

class EM_NET_CREATE_OBJECT_REQUEST

inherit

	EM_NET_2PC_EVENT_OBJECT

create {EM_NET_OBJECT_TYPES}

	make_set_type

feature -- Element change

	set_create_type_id (a_type_id: INTEGER) is
			-- Set `create_type_id' to `a_type_id'.
		do
			create_type_id := a_type_id
		end

feature -- Information

	create_type_id: INTEGER
			-- Type ID of the object that is requested

	create_group_name: STRING
			-- Name of the group in which the object will be created

feature -- Serialization

	serialize (a_serializer: EM_NET_SERIALIZER) is
			-- Serialize to the given stream using `a_serializer'.
		do
			a_serializer.put_integer (id)
			a_serializer.put_integer (create_type_id)
			a_serializer.put_integer (group.name.count)
			a_serializer.put_string (group.name)
		end

	serialization_byte_count: INTEGER is
			-- Count of bytes needed for a successful serialization
		do
			Result := 12 + group.name.count
		end

	unserialize (an_unserializer: EM_NET_UNSERIALIZER) is
			-- Unserialize from a given stream using `an_unserializer'.
		do
			an_unserializer.read_integer
			id := an_unserializer.last_integer
			an_unserializer.read_integer
			create_type_id := an_unserializer.last_integer
			an_unserializer.read_integer
			an_unserializer.read_string (an_unserializer.last_integer)
			create_group_name := an_unserializer.last_string
		end
end