indexing

	description: "[

		Event that requests destruction of a specific object from an other party.
		You need to specify the ID of the object that you request to be created.
		
		As response of this request an EM_NET_CREATE_OBJECT_RESPONSE might be sent.
		The object will (by default) be requested to be destroyed in the same group
		as the event is sent from.
		
		This event is only a request, no object will actually be destroyed. The receiver must
		decide on the action which follows this request.
		
		This is a secured two phase commit event.

	]"
	date: "$Date$"
	revision: "$Revision$"

class EM_NET_DESTROY_OBJECT_REQUEST

inherit

	EM_NET_2PC_EVENT_OBJECT

create {EM_NET_OBJECT_TYPES}

	make_set_type

feature -- Element change

	set_destroy_id (an_id: INTEGER) is
			-- Set `destroy_id' to `an_id'.
		do
			destroy_id := an_id
		end

feature -- Information

	destroy_id: INTEGER
			-- ID of the object that is requested to be destroyed

feature -- Serialization

	serialize (a_serializer: EM_NET_SERIALIZER) is
			-- Serialize to the given stream using `a_serializer'.
		do
			a_serializer.put_integer (id)
			a_serializer.put_integer (destroy_id)
		end

	serialization_byte_count: INTEGER is
			-- Count of bytes needed for a successful serialization
		do
			Result := 8
		end

	unserialize (an_unserializer: EM_NET_UNSERIALIZER) is
			-- Unserialize from a given stream using `an_unserializer'.
		do
			an_unserializer.read_integer
			id := an_unserializer.last_integer

			an_unserializer.read_integer
			destroy_id := an_unserializer.last_integer
		end

end