indexing

	description: "[

		Abstractions for drawable closed figures. Closed figures can be filled with a `fill_color'.

	]"
	date: "$Date$"
	revision: "$Revision$"

deferred class EM_CLOSED_FIGURE

inherit

	EM_FIGURE
		redefine
			default_create
		end

feature -- Initialization

	default_create is
			-- Initialize `Current' as filled figure
			-- in white colors with line width of 0.0.
		do
			Precursor {EM_FIGURE}
			create fill_color.make_white
			is_filled := True
			line_width := 0.0
		end

feature -- Status report

	fill_color: EM_COLOR
			-- The color with which the interrior of the figure is drawed,
			-- if `is_filled' is `True'

	is_filled: BOOLEAN
		-- Is `Current' drawed filled with `fill_color'?
		-- (otherwise only the border will be drawed)

feature -- Status setting

	set_filled (a_bool: BOOLEAN) is
			-- Set `is_filled' to `a_bool'.
		do
			is_filled := a_bool
		ensure
			is_filled_set: is_filled = a_bool
		end

	set_fill_color (a_color: EM_COLOR) is
			-- Set `fill_color' to `a_color'.
		require
			a_color_not_void: a_color /= Void
		do
			fill_color := a_color
		ensure
			fill_color_assigned: fill_color = a_color
		end

invariant

	fill_color_not_void: fill_color /= Void

end