indexing
	description: "[
	
		A plotter that renders a sequence of values as a colored ribbon (a line with depth)

	]"
	author: ""
	date: "$Date$"
	revision: "$Revision$"

class
	EM_VIZ_RIBBON_PLOTTER

inherit
	EM_VIZ_PLOTTER [EM_VECTOR2D]

create

	make

feature -- Initialization

	make (a_color: like ribbon_color)
			-- Make new plotter for ribbons of `a_color'
		require
			color_exists: a_color /= Void
		do
			set_ribbon_color (a_color)
		end

feature -- Access

	ribbon_color: EM_COLOR
			-- Color of ribbon

feature -- Element change

	set_ribbon_color (a_color: like ribbon_color) is
			-- Duh, set line color
		require
			color_exists: a_color /= Void
		do
			ribbon_color := a_color
		ensure
			set: ribbon_color = a_color
		end

feature -- Rendering

	plot (values: DS_LINEAR [EM_VECTOR2D]) is
			-- Plot values
		local
			v: EM_VECTOR2D
		do
			vz_color (ribbon_color)
			vz_normal3d (0, 0, 1)

			vz_begin_quad_strip
			from
				values.start
			until
				values.off
			loop
				v := values.item_for_iteration
				vz_vertex3d (v.x, v.y, 0.0)
				vz_vertex3d (v.x, v.y, -1.0)
				values.forth
			end
			vz_end
		end

end