note
	description: "Compiled class STRING"
	legal: "See notice at end of class."
	status: "See notice at end of class."
	date: "$Date$"
	revision: "$Revision$"

class STRING_CLASS_B

inherit
	EIFFEL_CLASS_C
		rename
			make as basic_make
		redefine
			check_validity
		end

	SPECIAL_CONST

create
	make

feature {NONE} -- Initialization

	make (l: like original_class; a_is_string_32: BOOLEAN)
			-- Representation of STRING_8 class if not `a_is_string_32', STRING_32 otherwise.			
		do
			basic_make (l)
			is_string_32 := a_is_string_32
		ensure
			is_string_32_set: is_string_32 = a_is_string_32
		end

feature -- Property

	is_string_32: BOOLEAN
			-- Is current class the STRING_32 classe?

feature -- Checking

	check_validity
			-- Check validity of class STRING
		local
			set_count_feat: FEATURE_I;
			internal_hash_code_feat: ATTRIBUTE_I
			error, done: BOOLEAN;
			special_error: SPECIAL_ERROR;
			creat_feat: FEATURE_I;
			area_feature: FEATURE_I
		do
				-- Check if class has an attribute `area' of type SPECIAL [CHARACTER].
			area_feature ?= feature_table.item_id (Names_heap.area_name_id)
			if
				(area_feature = Void)
				or else not area_type.same_as (area_feature.type.actual_type)
			then
				create special_error.make (string_case_1, Current)
				Error_handler.insert_error (special_error)
			end

				-- Second check if class has only one reference attribute
				-- only (which is necessary `area' then).
			if types.first.skeleton.nb_reference /= 1 then
				create special_error.make (string_case_2, Current);
				Error_handler.insert_error (special_error);
			end;

				-- Third check if class has one creation procedure with
				-- one integer argument
			error := creators = Void
			if not error then
				from
					creators.start
				until
					done or else creators.after
				loop
					creat_feat := feature_table.item (creators.key_for_iteration);
					if
						creat_feat.feature_name_id = names_heap.make_name_id and then
						creat_feat.same_signature (make_signature)
					then
						done := True
					else
						creators.forth
					end
				end
				error := not done
			end;
			if error then
				create special_error.make (string_case_3, Current);
				Error_handler.insert_error (special_error);
			end;

				-- Fourthsence of a procedure `set_count'.
			set_count_feat := feature_table.item_id (Names_heap.set_count_name_id);
			if 	set_count_feat = Void
				or else
				(not set_count_feat.same_signature (set_count_signature))
				or else
				not (set_count_feat.written_in = class_id)
			then
				create special_error.make (string_case_4, Current);
				Error_handler.insert_error (special_error);
			end;

			if not System.il_generation then
					-- Presence of attribute `internal_hash_code'.
				internal_hash_code_feat ?=
					feature_table.item_id (Names_heap.internal_hash_code_name_id)
				if
					internal_hash_code_feat = Void or else
					not internal_hash_code_feat.type.same_as (Integer_type)
				then
					create special_error.make (string_case_5, Current)
					Error_handler.insert_error (special_error)
				end

					-- Presence of attribute `count'.
				if
					not attached feature_table.item_id (Names_heap.count_name_id) as l_feat or else
					not l_feat.is_attribute or else not l_feat.type.same_as (integer_32_type)
				then
					create special_error.make (string_case_6, Current)
					Error_handler.insert_error (special_error)
				end
			else
					-- Presence of `to_cil'.
				if
					not attached feature_table.item_id ({PREDEFINED_NAMES}.to_cil_name_id) as l_feat or else
					l_feat.has_arguments or else not l_feat.has_return_value or else
					l_feat.type.base_class.class_id /= system.system_string_id
				then
					create special_error.make (string_case_7, Current)
					Error_handler.insert_error (special_error)
				end
			end
		end

feature {NONE} -- Implementation

	make_signature: DYN_PROC_I
			-- Required signature for feature `make' of class STRING
		local
			args: FEAT_ARG;
		do
			create args.make (1);
			args.extend (Integer_type);
			create Result;
			Result.set_arguments (args);
			Result.set_feature_name_id (Names_heap.make_name_id, 0)
		end;

	area_type: GEN_TYPE_A
			-- Type SPECIAL [CHARACTER]
		local
			gen: ARRAYED_LIST [TYPE_A]
		do
			create gen.make (1)
			if is_string_32 then
				gen.extend (wide_char_type)
			else
				gen.extend (character_type)
			end
			create Result.make (System.special_id, gen)
		ensure
			area_type_not_void: Result /= Void
		end

	set_count_signature: DYN_PROC_I
			-- Required signature for `set_count' of class STRING
		local
			args: FEAT_ARG;
		do
			create args.make (1);
			args.extend (Integer_type);
			create Result;
			Result.set_arguments (args);
			Result.set_feature_name_id (Names_heap.set_count_name_id, 0)
		end;

note
	copyright:	"Copyright (c) 1984-2014, Eiffel Software"
	license:	"GPL version 2 (see http://www.eiffel.com/licensing/gpl.txt)"
	licensing_options:	"http://www.eiffel.com/licensing"
	copying: "[
			This file is part of Eiffel Software's Eiffel Development Environment.
			
			Eiffel Software's Eiffel Development Environment is free
			software; you can redistribute it and/or modify it under
			the terms of the GNU General Public License as published
			by the Free Software Foundation, version 2 of the License
			(available at the URL listed under "license" above).
			
			Eiffel Software's Eiffel Development Environment is
			distributed in the hope that it will be useful, but
			WITHOUT ANY WARRANTY; without even the implied warranty
			of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
			See the GNU General Public License for more details.
			
			You should have received a copy of the GNU General Public
			License along with Eiffel Software's Eiffel Development
			Environment; if not, write to the Free Software Foundation,
			Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
		]"
	source: "[
			Eiffel Software
			5949 Hollister Ave., Goleta, CA 93117 USA
			Telephone 805-685-1006, Fax 805-685-6869
			Website http://www.eiffel.com
			Customer support http://support.eiffel.com
		]"

end