indexing 
	description: "WIZARD_PS_DIALOG class created by Resource Bench."

class 
	WIZARD_PS_DIALOG

inherit
	WIZARD_DIALOG
		redefine
			setup_dialog,
			on_ok,
			notify
		end

	APPLICATION_IDS
		export
			{NONE} all
		end

creation
	make

feature {NONE} -- Initialization

	make (a_parent: WEL_COMPOSITE_WINDOW) is
			-- Create the dialog.
		require
			a_parent_not_void: a_parent /= Void
			a_parent_exists: a_parent.exists
		do
			make_by_id (a_parent, Wizard_ps_dialog_constant)
			create virtual_table_standard_radio.make_by_id (Current, Virtual_table_standard_radio_constant)
			create automation_radio.make_by_id (Current, Automation_radio_constant)
			create virtual_table_universal_radio.make_by_id (Current, Virtual_table_universal_radio_constant)
			create id_ok.make_by_id (Current, Idok)
			create proxy_stub_input_edit.make_by_id (Current, Proxy_stub_input_edit_constant)
			create id_back.make_by_id (Current, id_back_constant)
			create browse_button.make_by_id (Current, Browse_button_constant)
			create help_button.make_by_id (Current, Help_button_constant)
			help_topic_id := 736
			create id_cancel.make_by_id (Current, Idcancel)
			create msg_box.make
		end

feature -- Behavior

	notify (control: WEL_CONTROL; notify_code: INTEGER) is
		do
			if control = virtual_table_standard_radio then
				proxy_stub_input_edit.enable
				browse_button.enable
			elseif control = virtual_table_universal_radio or control = automation_radio then
				proxy_stub_input_edit.disable
				browse_button.disable
			elseif control = browse_button then
				File_selection_dialog.activate (Current)
				if File_selection_dialog.selected then
					proxy_stub_input_edit.set_text (file_selection_dialog.file_name)
				end				
			end
		end

	setup_dialog is
			-- Initialize radio buttons.
		do
			Precursor {WIZARD_DIALOG}
			uncheck_all
			if Shared_wizard_environment.automation then
				automation_radio.set_checked
			else
				if Shared_wizard_environment.use_universal_marshaller then
					virtual_table_universal_radio.set_checked
				else
					virtual_table_standard_radio.set_checked
					proxy_stub_input_edit.enable
				end
			end
			if shared_wizard_environment.proxy_stub_file_name /= Void then
				proxy_stub_input_edit.set_text (shared_wizard_environment.proxy_stub_file_name)
			end
		end

	on_ok is
			-- Process next button activation
		local
			a_file: RAW_FILE
		do
			Shared_wizard_environment.set_automation (automation_radio.checked)
			shared_wizard_environment.set_use_universal_marshaller (virtual_table_universal_radio.checked or automation_radio.checked)
			if virtual_table_standard_radio.checked then
				if proxy_stub_input_edit.text /= Void and then not proxy_stub_input_edit.text.is_empty then
					!! a_file.make (proxy_stub_input_edit.text)
					if a_file.exists then
						shared_wizard_environment.set_proxy_stub_file_name (proxy_stub_input_edit.text)
						Precursor {WIZARD_DIALOG}
					else
						msg_box.error_message_box (Current, Proxy_stub_file_not_valid, Wizard_error_message)
					end
				else
					msg_box.error_message_box (Current, Proxy_stub_file_not_valid, Wizard_error_message)
				end
			else
				Precursor {WIZARD_DIALOG}
			end
		end

feature -- Access

	automation_radio: WEL_RADIO_BUTTON
			-- Automation server type radio button

	virtual_table_standard_radio: WEL_RADIO_BUTTON
			-- Virtual Table and standard marshalling server type radio button

	virtual_table_universal_radio: WEL_RADIO_BUTTON
			-- Virtual Table and universal marshalling server type radio button

	proxy_stub_input_edit: WEL_SINGLE_LINE_EDIT
			-- Proxy/Stub file edit
 
	browse_button: WEL_PUSH_BUTTON
			-- Browse button

	File_selection_dialog: WEL_OPEN_FILE_DIALOG is
			-- File selection dialog
		once
			create Result.make
			Result.set_filter (<<"Proxy Stub File (*.dll)">>, <<"*.dll">>)
		end

	msg_box: WEL_MSG_BOX
			-- Message box

feature {NONE} -- Implementation

	uncheck_all is
			-- Uncheck all buttons.
		do
			automation_radio.set_unchecked
			virtual_table_standard_radio.set_unchecked
			virtual_table_universal_radio.set_unchecked
			browse_button.disable
			proxy_stub_input_edit.disable
		end

	Proxy_stub_file_not_valid: STRING is "Marshaller file not valid!"
			-- Invalid proxy/stub file error message

	Wizard_error_message: STRING is "Wizard error"
			-- Error message title

end -- class WIZARD_PS_DIALOG

--|-------------------------------------------------------------------
--| This class was automatically generated by Resource Bench
--| Copyright (C) 1996-1997, Interactive Software Engineering, Inc.
--|
--| 270 Storke Road, Suite 7, Goleta, CA 93117 USA
--| Telephone 805-685-1006
--| Fax 805-685-6869
--| Information e-mail <info@eiffel.com>
--| Customer support e-mail <support@eiffel.com>
--|-------------------------------------------------------------------