note

	description: "Error with bracket expression"
	legal: "See notice at end of class."
	status: "See notice at end of class.";
	date: "$Date$";
	revision: "$Revision$"

deferred class VWBR

inherit

	FEATURE_ERROR
		undefine
			subcode
		redefine
			build_explain, is_defined
		end

feature -- Properties

	target_type: detachable TYPE_A
			-- Target type for which bracket expression is applied

	target_type_set: detachable TYPE_SET_A
			-- Target type set for which bracket expression is applied

	code: STRING = "VWBR"
			-- Error code

feature -- Access

	is_defined: BOOLEAN
			-- Is the error fully defined?
		do
			Result := is_class_defined and then (target_type /= Void or target_type_set /= Void)
		end

feature -- Output

	build_explain (a_text_formatter: TEXT_FORMATTER)
			-- Build specific explanation image for current error
			-- in `a_text_formatter'.
		do
			if target_type /= Void then
				if target_type.has_associated_class then
					a_text_formatter.add ("Target class: ")
					target_type.base_class.append_name (a_text_formatter)
				end
			end
			if target_type_set /= Void then
				a_text_formatter.add ("Target class set: ")
				target_type_set.append_to (a_text_formatter)
			end
			a_text_formatter.add_new_line
		end

feature {COMPILER_EXPORTER} -- Setting

	set_target_type (t: TYPE_A)
			-- Assign `t' to `target_type'.
		require
			t_not_void: t /= Void
			t_has_associated_class: t.has_associated_class
		do
			target_type := t
		end

	set_target_type_set (t: like target_type_set)
			-- Assign `t' to `target_type_set'.
		require
			t_not_void: t /= Void
			t_has_associated_class: not t.is_loose
		do
			target_type_set := t
		end

note
	copyright:	"Copyright (c) 1984-2012, Eiffel Software"
	license:	"GPL version 2 (see http://www.eiffel.com/licensing/gpl.txt)"
	licensing_options:	"http://www.eiffel.com/licensing"
	copying: "[
			This file is part of Eiffel Software's Eiffel Development Environment.
			
			Eiffel Software's Eiffel Development Environment is free
			software; you can redistribute it and/or modify it under
			the terms of the GNU General Public License as published
			by the Free Software Foundation, version 2 of the License
			(available at the URL listed under "license" above).
			
			Eiffel Software's Eiffel Development Environment is
			distributed in the hope that it will be useful, but
			WITHOUT ANY WARRANTY; without even the implied warranty
			of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
			See the GNU General Public License for more details.
			
			You should have received a copy of the GNU General Public
			License along with Eiffel Software's Eiffel Development
			Environment; if not, write to the Free Software Foundation,
			Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
		]"
	source: "[
			Eiffel Software
			5949 Hollister Ave., Goleta, CA 93117 USA
			Telephone 805-685-1006, Fax 805-685-6869
			Website http://www.eiffel.com
			Customer support http://support.eiffel.com
		]"

end