note
	description: "Abstract description of an Eiffel routine object in agent form"
	legal: "See notice at end of class."
	status: "See notice at end of class."
	author: ""
	date: "$Date$"
	revision: "$Revision$"

class
	AGENT_ROUTINE_CREATION_AS

inherit
	ROUTINE_CREATION_AS
		redefine
			process
		end

create
	make

feature{NONE} -- Initialization

	make (t: like target; f: like feature_name; o: like internal_operands; ht: BOOLEAN; a_as: like agent_keyword; d_as: like dot_symbol)
			-- Create a new ROUTINE_CREATION AST node.
			-- When `t' is Void it means it is a question mark.
		do
			initialize (t, f, o, ht)
			if a_as /= Void then
				agent_keyword_index := a_as.index
			end
			if d_as /= Void then
				dot_symbol_index := d_as.index
			end
		ensure
			agent_keyword_set: a_as /= Void implies agent_keyword_index = a_as.index
			dot_symbol_set: d_as /= Void implies dot_symbol_index = d_as.index
			no_routine_id: routine_ids.is_empty
		end

feature -- Visitor

	process (v: AST_VISITOR)
			-- process current element.
		do
			v.process_agent_routine_creation_as (Current)
		end

feature -- Roundtrip

	agent_keyword_index: INTEGER
			-- Index of keyword "agent" associated with this structure

	dot_symbol_index: INTEGER
			-- Index of symbol "." associated with this structure

	agent_keyword (a_list: LEAF_AS_LIST): detachable KEYWORD_AS
			-- Keyword "agent" associated with this structure
		require
			a_list_not_void: a_list /= Void
		do
			Result := keyword_from_index (a_list, agent_keyword_index)
		end

	dot_symbol (a_list: LEAF_AS_LIST): detachable SYMBOL_AS
			-- Symbol "." associated with this structure
		require
			a_list_not_void: a_list /= Void
		do
			Result := symbol_from_index (a_list, dot_symbol_index)
		end

	index: INTEGER
			-- <Precursor>
		do
			Result := agent_keyword_index
		end

feature -- Roundtrip/Token

	first_token (a_list: detachable LEAF_AS_LIST): detachable LEAF_AS
		do
			if a_list = Void then
				if attached target as l_target then
					Result := l_target.first_token (a_list)
				end
				if (Result = Void or else Result.is_null) and then attached feature_name as l_name then
					Result := l_name.first_token (a_list)
				end
			elseif agent_keyword_index /= 0 then
				Result := agent_keyword (a_list)
			end
		end

	last_token (a_list: detachable LEAF_AS_LIST): detachable LEAF_AS
		do
			if a_list = Void then
				if attached operands as l_operands then
					Result := l_operands.last_token (a_list)
				elseif attached feature_name as l_name then
					Result := l_name.last_token (a_list)
				end
			else
				if attached internal_operands as l_operands then
					Result := l_operands.last_token (a_list)
				elseif attached feature_name as l_name then
					Result := l_name.last_token (a_list)
				end
			end
		end

note
	copyright:	"Copyright (c) 1984-2015, Eiffel Software"
	license:	"GPL version 2 (see http://www.eiffel.com/licensing/gpl.txt)"
	licensing_options:	"http://www.eiffel.com/licensing"
	copying: "[
			This file is part of Eiffel Software's Eiffel Development Environment.
			
			Eiffel Software's Eiffel Development Environment is free
			software; you can redistribute it and/or modify it under
			the terms of the GNU General Public License as published
			by the Free Software Foundation, version 2 of the License
			(available at the URL listed under "license" above).
			
			Eiffel Software's Eiffel Development Environment is
			distributed in the hope that it will be useful, but
			WITHOUT ANY WARRANTY; without even the implied warranty
			of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
			See the GNU General Public License for more details.
			
			You should have received a copy of the GNU General Public
			License along with Eiffel Software's Eiffel Development
			Environment; if not, write to the Free Software Foundation,
			Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
		]"
	source: "[
			Eiffel Software
			5949 Hollister Ave., Goleta, CA 93117 USA
			Telephone 805-685-1006, Fax 805-685-6869
			Website http://www.eiffel.com
			Customer support http://support.eiffel.com
		]"

end