indexing
	description: "This client changes the shared hierarchy of a listening application. "
	library: "elogger"
	copyright: "Copyright (c) 2006, AXA Rosenberg, and others (see copyright.txt)"
	author: "Ulrich Weiss, and others"
	license: "Eiffel Forum License v2 (see forum.txt)"
	date: "$Date: $"
	revision: "$Revision: $"
	archive: "$Archive: $"

class ELOG_TEST_CONFIGURATION_CLIENT_HIERARCHY

inherit

	ELOG_SEVERITY_CONSTANTS
		export
			{NONE} all
		end

	ELOG_SHARED_INTERNAL_LOGGER
		export
			{NONE} all
		end

	NETWORK_CLIENT
		rename
			make as client_make
		end

creation

	make

feature {NONE} -- Initialization

	make (new_host: STRING; new_port: INTEGER) is
			-- Initialise socket appender that will send events to
			-- the TCP socket server listening at 'host' on 'port'.
		require
			host_exists: new_host /= Void
			positive_port: new_port >= 0
		local
			rescued: BOOLEAN
		do
			if not rescued then
				host := new_host
				port := new_port
				if new_port = 0 then
					port := Default_port
				end

				client_make (port, host)

				if not socket_ok then
					internal_logger.log_fatal (create {ELOG_SIMPLE_EVENT}.make ("Error: Failed to connect to socket. "))
				else
					send ("file:elogger/test/elogger_sample_config.xml")
					cleanup
				end
			end
		rescue
			rescued := True
			retry
		end

feature {NONE} -- Implementation

	port: INTEGER
			-- Connection port

	host: STRING
			-- Connection host

	Default_port: INTEGER is 8906
			-- default port

end