indexing
	description: "test the configuration file parser. "
	library: "elogger"
	copyright: "Copyright (c) 2006, AXA Rosenberg, and others (see copyright.txt)"
	author: "Ulrich Weiss, and others"
	license: "Eiffel Forum License v2 (see forum.txt)"
	date: "$Date: $"
	revision: "$Revision: $"
	archive: "$Archive: $"

deferred class TEST_ELOG_CONFIG_PARSER

inherit

    TS_TEST_CASE
    	undefine
    		name_of_id,
    		execute_i_th
    	end

    ELOG_SEVERITY_CONSTANTS

	KL_SHARED_OPERATING_SYSTEM
    	export
    		{NONE}	all
    	end

feature -- Test

	test_parser is
            -- Test load an example parser and compare the settings.
        local
            parser: ELOG_XML_CONFIG_PARSER
            h: ELOG_HIERARCHY
        do
			create parser.make ("elogger/test/elogger_sample_config.xml")
			h := parser.hierarchy

			assert ("logger_a_exists", h.has ("a"))
			assert ("logger_b_exists", h.has ("b"))

			assert ("set a", h.logger ("a").severity = Warning_severity)
			assert ("set b", h.logger ("b").severity = Fatal_severity)
			assert ("set root", h.root.severity = Minor_severity)

			assert ("has appender", h.root.has_appender_by_name ("app.log"))
			assert ("has appender", h.root.has_appender_by_name ("app-c.log"))
			assert ("has appender", h.logger ("a").has_appender_by_name ("app.log"))
			assert ("has appender", h.logger ("a").has_appender_by_name ("app-c.log"))
			assert ("has appender", h.logger ("b").has_appender_by_name ("app-b.log"))
			assert ("appender is asynchronous", h.logger ("b").get_appender_by_name ("app-b.log").is_synchronous = False)
			assert ("appender is asynchronous", h.logger ("a").get_appender_by_name ("app-c.log").is_synchronous = True)
			assert ("has appender", h.logger ("b").has_appender_by_name ("std"))

			h.close_all
			delete_file ("app.log")
			delete_file ("app-b.log")
			delete_file ("app-c.log")
        end

	delete_file (filename: STRING) is
    		-- delete a certain file
    	require
    		filename_not_void: filename /= Void
    	local
    		stream: KI_TEXT_INPUT_FILE
    	do
    		if operating_system.is_windows then
				stream := create {KL_WINDOWS_INPUT_FILE}.make (filename)
			else
				stream := create {KL_UNIX_INPUT_FILE}.make (filename)
			end
			stream.delete
    	end

end