indexing
	description: "Represents an activeMQ connection factory"
	author: "Patrick Ruckstuhl <patrick@tario.org>"
	date: "$Date$"
	revision: "$Revision$"

class
	ACTIVEMQ_CONNECTION_FACTORY

inherit
	WRAPPER_BASE
		rename
			make as make_base
		end

create
	make

feature -- Initialization

	make (a_broker_url: STRING) is
			-- Create.
		local
			l_broker_url: C_STRING
		do
			create l_broker_url.make (a_broker_url)
			make_base (cpp_new(l_broker_url.item))
		end

feature -- Object creation

	create_connection: CONNECTION is
			-- Create a new connection.
		do
			create Result.make(cpp_create_connection(item))
		end

feature {NONE} -- C++ methods

	cpp_new (a_string: POINTER): POINTER is
			-- Create new cpp object.
		external
			"C++ inline use <activemq/core/ActiveMQConnectionFactory.h>"
		alias
			"[
			try{
			return new activemq::core::ActiveMQConnectionFactory((char*)$a_string);
			}catch(cms::CMSException& e){
			eraise((char*)(e.getStackTraceString().c_str()), EN_PROG);
			}
			 ]"
		end

	cpp_create_connection (a_object: POINTER): POINTER is
			-- Create a connection.
		external
			"C++ inline use <activemq/core/ActiveMQConnectionFactory.h>"
		alias
			"[
			try{
			return ((activemq::core::ActiveMQConnectionFactory*)$a_object)->createConnection();
			}catch(cms::CMSException& e){
			eraise((char*)(e.getStackTraceString().c_str()), EN_PROG);
			}
			 ]"
		end

	cpp_delete (a_object: POINTER) is
			-- Delete cpp object
		external
			"C++ inline use <activemq/core/ActiveMQConnectionFactory.h>"
		alias
			"[
			delete (activemq::core::ActiveMQConnectionFactory*)$a_object;
			 ]"
		end


end