indexing
	description: "A connection."
	author: "Patrick Ruckstuhl <patrick@tario.org>"
	date: "$Date$"
	revision: "$Revision$"

class
	CONNECTION

inherit
	WRAPPER_BASE

create {ACTIVEMQ_CONNECTION_FACTORY}
	make

feature -- Update

	set_exception_listener (an_exception_listener: EXCEPTION_LISTENER) is
			-- Set the exception listener.
		do
			cpp_set_exception_listener (item, an_exception_listener.item)
		end

feature -- Actions

	start is
			-- Start the connection.
		do
			cpp_start (item)
		end

	close is
			-- Close.
		do
			cpp_close (item)
		end

feature -- Object creation

	create_session_auto_ack: SESSION is
			-- Create a session.
		do
			create Result.make (cpp_create_session (item))
		end

	create_session_client_ack: SESSION is
			-- Create a session.
		do
			create Result.make (cpp_create_session_client_ack (item))
		end


feature {NONE} -- C++ methods

	cpp_delete (a_object: POINTER) is
			-- Delete cpp object.
		external
			"C++ inline use <cms/Connection.h>"
		alias
			"[
			delete (cms::Connection*)$a_object;
			 ]"
		end

	cpp_start (a_object: POINTER) is
			-- Start the connection.
		external
			"C++ inline use <cms/Connection.h>"
		alias
			"[
			try{
			((cms::Connection*)$a_object)->start();
			}catch(cms::CMSException& e){
			eraise((char*)(e.getStackTraceString().c_str()), EN_PROG);
			}
			 ]"
		end

	cpp_close (a_object: POINTER) is
			-- Close the connection.
		external
			"C++ inline use <cms/Connection.h>"
		alias
			"[
			try{
			((cms::Connection*)$a_object)->close();
			}catch(cms::CMSException& e){
			eraise((char*)(e.getStackTraceString().c_str()), EN_PROG);
			}
			 ]"
		end

	cpp_create_session (a_object: POINTER): POINTER is
			-- Create a new session.
		external
			"C++ inline use <cms/Connection.h>"
		alias
			"[
			try{
			return ((cms::Connection*)$a_object)->createSession();
			}catch(cms::CMSException& e){
			eraise((char*)(e.getStackTraceString().c_str()), EN_PROG);
			}
			 ]"
		end

	cpp_create_session_client_ack (a_object: POINTER): POINTER is
			-- Create a new session.
		external
			"C++ inline use <cms/Connection.h>,<cms/Session.h>"
		alias
			"[
			try{
			return ((cms::Connection*)$a_object)->createSession(cms::Session::CLIENT_ACKNOWLEDGE);
			}catch(cms::CMSException& e){
			eraise((char*)(e.getStackTraceString().c_str()), EN_PROG);
			}
			 ]"
		end

	cpp_set_exception_listener (a_object: POINTER; a_listener: POINTER) is
			-- Set the exception listener.
		external
			"C++ inline use <cms/Connection.h>,<cms/ExceptionListener.h>"
		alias
			"[
			((cms::Connection*)$a_object)->setExceptionListener((cms::ExceptionListener*)$a_listener);
			]"
		end
end