indexing
	description: "Represents the world peer group id"
	license: "MIT license (see ../license.txt)"
	author: "Beat Strasser <beat@stradax.net>"
	date: "$Date$"
	revision: "$Revision$"

class
	P2P_WORLDGROUP_ID

inherit
	P2P_PEERGROUP_ID
		redefine
			is_unique_id_valid
		end

create
	make_from_urn,
	make

feature {NONE} -- Initialization

	make is
			-- Create null id
		do
			make_with_id (worldgroup)
		end

feature -- Access

	format: STRING is "jxta"

	parent_peer_group_id: P2P_PEERGROUP_ID is
			-- World group has no parent group.
		do
			Result := Current
		ensure
			Result_set: Result /= Void
		end

	uuid: ARRAY [NATURAL_8] is
			-- World group UUID (for creating children)
		indexing
			once_status: global
		once
			-- 0x59616261646162614A78746150325033 (YabadabaJxtaP2P3)
			create Result.make (0, 15)
			Result[0] := 0x59
			Result[1] := 0x61
			Result[2] := 0x62
			Result[3] := 0x61
			Result[4] := 0x64
			Result[5] := 0x61
			Result[6] := 0x62
			Result[7] := 0x61
			Result[8] := 0x4A
			Result[9] := 0x78
			Result[10] := 0x74
			Result[11] := 0x61
			Result[12] := 0x50
			Result[13] := 0x32
			Result[14] := 0x50
			Result[15] := 0x33
		ensure
			Result_set: Result /= Void
		end

	is_worldgroup_id: BOOLEAN is True
			-- Is current id the world group id?

	is_netgroup_id: BOOLEAN is False
			-- Is current id the net group id?

feature {NONE} -- Implementation

	is_unique_id_valid (an_id: STRING): BOOLEAN is
			-- Is `an_id' WorldGroup?
		do
			Result := worldgroup.is_equal (an_id)
		end

	Worldgroup: STRING is "WorldGroup"

end