indexing
	description: "Tests the module class id"
	license: "MIT license (see ../../license.txt)"
	author: "Beat Strasser <beat@stradax.net>"
	date: "$Date$"
	revision: "$Revision$"

deferred class
	TEST_MODULE_CLASS_ID

inherit
	TS_TEST_CASE

feature -- Tests

	test_make is
			-- Test make
		local
			mcid: P2P_MODULE_CLASS_ID
		do
			create mcid.make (tcuuid, truuid)
			validate (mcid)
		end

	test_make_from_urn is
			-- Test make_from_urn
		local
			mcid: P2P_MODULE_CLASS_ID
		do
			create mcid.make_from_urn ("urn:jxta:uuid-" + tid)
			validate (mcid)
		end

	validate (mcid: P2P_MODULE_CLASS_ID) is
			-- Validate mcid
		require
			Mcid_valid: mcid /= Void
		do
			assert_true ("is_valid", mcid.is_valid)
			assert_equal ("format", "uuid", mcid.format)
			assert_equal ("unique id", tid, mcid.unique_id)
			assert_true ("unique id valid", mcid.is_unique_id_valid (mcid.unique_id))
			assert_equal ("out", "urn:jxta:uuid-" + tid, mcid.out)
			assert_equal ("out_short", "uuid-" + tid, mcid.out_short)
			assert_equal ("flag id type", {NATURAL_8} 5, mcid.flag_id_type)
			assert_equal ("class uuid", tcuuid, mcid.uuid)
			assert_true ("base_class_id", mcid.base_class_id.is_valid)
		end

	test_make_new is
			-- Test make_new
		local
			mcid: P2P_MODULE_CLASS_ID
		do
			create mcid.make_new
			assert_true ("is_valid", mcid.is_valid)
			assert_equal ("format", "uuid", mcid.format)
			assert_equal ("unique id", "05", mcid.unique_id.substring (mcid.unique_id.count - 1, mcid.unique_id.count))
			assert_true ("unique id valid", mcid.is_unique_id_valid (mcid.unique_id))
			assert_equal ("out", "urn:jxta:uuid-", mcid.out.substring (1, 14))
			assert_equal ("out_short", "uuid-", mcid.out_short.substring (1, 5))
			assert_equal ("flag id type", {NATURAL_8} 5, mcid.flag_id_type)
			assert_equal ("class uuid", 16, mcid.uuid.count)
			assert_true ("base_class_id", mcid.base_class_id.is_valid)
		end

	test_base_class is
			-- Test has_same_baseclass
		local
			mcid1, mcid2: P2P_MODULE_CLASS_ID
			truuid2: ARRAY [NATURAL_8]
		do
			create mcid1.make (tcuuid, truuid)
			create truuid2.make (0, 15)
			create mcid2.make (tcuuid, truuid2)
			assert_true ("has_same_baseclass", mcid1.has_same_baseclass (mcid2))
		end

feature {NONE} -- Test data

	tid: STRING is "B6228B74806B456281AF9854A151F11DF592E37849884567B82EA12C0850E15B05"

	tcuuid: ARRAY [NATURAL_8] is
			-- Class UUID
		once
			Result := << 0x22, 0x8B, 0x74, 0x80, 0x6B, 0x45, 0x62, 0x81, 0xAF, 0x98, 0x54, 0xA1, 0x51, 0xF1, 0x1D >>
			Result.force (0xB6, 0)
		end

	truuid: ARRAY [NATURAL_8] is
			-- Role UUID
		once
			Result := << 0x92, 0xE3, 0x78, 0x49, 0x88, 0x45, 0x67, 0xB8, 0x2E, 0xA1, 0x2C, 0x08, 0x50, 0xE1, 0x5B >>
			Result.force (0xF5, 0)
		end

end