indexing
	description: "Tests the peer group id"
	license: "MIT license (see ../../license.txt)"
	author: "Beat Strasser <beat@stradax.net>"
	date: "$Date$"
	revision: "$Revision$"

deferred class
	TEST_PEERGROUP_ID

inherit
	TS_TEST_CASE
	P2P_CREATORS_SHARED

feature -- Tests

	test_make is
			-- Test make
		local
			gid: P2P_PEERGROUP_UUID
		do
			create gid.make (tguuid, tpuuid)
			validate (gid)
		end

	test_make_from_urn is
			-- Test make_from_urn
		local
			gid: P2P_PEERGROUP_UUID
		do
			create gid.make_from_urn ("urn:jxta:uuid-" + tid)
			validate (gid)
		end

	validate (gid: P2P_PEERGROUP_UUID) is
			-- Validate gid
		require
			Gid_valid: gid /= Void
		do
			assert_true ("is_valid", gid.is_valid)
			assert_equal ("format", "uuid", gid.format)
			assert_equal ("unique id", tid, gid.unique_id)
			assert_true ("unique id valid", gid.is_unique_id_valid (gid.unique_id))
			assert_equal ("out", "urn:jxta:uuid-" + tid, gid.out)
			assert_equal ("out_short", "uuid-" + tid, gid.out_short)
			assert_equal ("flag id type", {NATURAL_8} 2, gid.flag_id_type)
			assert_equal ("group id", tguuid, gid.uuid)
			assert_equal ("parent uuid", tpuuid, gid.parent_peer_group_id.uuid)
			assert_false ("is_npg", gid.is_netgroup_id)
			assert_false ("is_wpg", gid.is_worldgroup_id)
		end

	test_make_with_uuid is
			-- Test make_with_uuid
		local
			gid: P2P_PEERGROUP_UUID
		do
			create gid.make_with_uuid (tguuid)
			assert_true ("is_valid", gid.is_valid)
			assert_equal ("format", "uuid", gid.format)
			assert_equal ("unique id", tid.substring (1, 32), gid.unique_id.substring (1, 32))
			assert_true ("unique id valid", gid.is_unique_id_valid (gid.unique_id))
			assert_equal ("out", "urn:jxta:uuid-" + tid.substring (1, 32), gid.out.substring (1, 46))
			assert_equal ("out_short", "uuid-" + tid.substring (1, 32), gid.out_short.substring (1, 37))
			assert_equal ("flag id type", {NATURAL_8} 2, gid.flag_id_type)
			assert_equal ("group id", tguuid, gid.uuid)
			assert_false ("is_npg", gid.is_netgroup_id)
			assert_false ("is_wpg", gid.is_worldgroup_id)
		end

	test_make_new_with_parent is
			-- Test make_new_with_parent
		local
			gid: P2P_PEERGROUP_UUID
		do
			create gid.make_new_with_parent (tpuuid)
			assert_true ("is_valid", gid.is_valid)
			assert_equal ("format", "uuid", gid.format)
			assert_equal ("unique id", tid.substring (33, 64), gid.unique_id.substring (33, 64))
			assert_true ("unique id valid", gid.is_unique_id_valid (gid.unique_id))
			assert_equal ("out 1", "urn:jxta:uuid-", gid.out.substring (1, 14))
			assert_equal ("out 2", tid.substring (33, 64) + "02", gid.out.substring (47, gid.out.count))
			assert_equal ("out_short", tid.substring (33, 64) + "02", gid.out_short.substring (38, gid.out_short.count))
			assert_equal ("flag id type", {NATURAL_8} 2, gid.flag_id_type)
			assert_equal ("group id", 16, gid.uuid.count)
			assert_equal ("parent uuid", tpuuid, gid.parent_peer_group_id.uuid)
			assert_false ("is_npg", gid.is_netgroup_id)
			assert_false ("is_wpg", gid.is_worldgroup_id)
		end

	test_jxta_groups is
			-- Test is_netgroup_id/is_worldgroup_id
		local
			gid: P2P_PEERGROUP_UUID
		do
			create gid.make_with_uuid (id_creator.netgroup_id.uuid)
			assert_true ("is_npg", gid.is_netgroup_id)
			assert_false ("is_wpg", gid.is_worldgroup_id)
			create gid.make_with_uuid (id_creator.worldgroup_id.uuid)
			assert_false ("is_npg", gid.is_netgroup_id)
			assert_true ("is_wpg", gid.is_worldgroup_id)
		end

feature {NONE} -- Test data

	tid: STRING is "B6228B74806B456281AF9854A151F11DF592E37849884567B82EA12C0850E15B02"

	tguuid: ARRAY [NATURAL_8] is
			-- Group UUID
		once
			Result := << 0x22, 0x8B, 0x74, 0x80, 0x6B, 0x45, 0x62, 0x81, 0xAF, 0x98, 0x54, 0xA1, 0x51, 0xF1, 0x1D >>
			Result.force (0xB6, 0)
		end

	tpuuid: ARRAY [NATURAL_8] is
			-- Parent group UUID
		once
			Result := << 0x92, 0xE3, 0x78, 0x49, 0x88, 0x45, 0x67, 0xB8, 0x2E, 0xA1, 0x2C, 0x08, 0x50, 0xE1, 0x5B >>
			Result.force (0xF5, 0)
		end

end