/[eiffelstudio]/branches/CAT_mono/Src/Eiffel/eiffel/genericity/cl_type_i.e
ViewVC logotype

Contents of /branches/CAT_mono/Src/Eiffel/eiffel/genericity/cl_type_i.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 44058 - (show annotations)
Wed Jun 30 23:08:24 2004 UTC (15 years, 8 months ago) by manus
Original Path: trunk/Src/bench/Eiffel/eiffel/genericity/cl_type_i.e
File size: 13405 byte(s)
Changed `is_generated_as_single_type' to be only true for external classes
  and classes which are `is_single'. All other eiffel classes gets an interface
  and an implementation.
Removed comment on `element_type' about the `is_expanded' case since we partially
  support expanded types in IL code generation now.

1 indexing
2 description: "Type class."
3 date: "$Date$"
4 revision: "$Revision$"
5
6 class CL_TYPE_I
7
8 inherit
9 TYPE_I
10 redefine
11 is_reference,
12 is_expanded,
13 is_separate,
14 is_valid,
15 is_explicit,
16 is_external,
17 same_as,
18 c_type,
19 conforms_to_array,
20 generated_id,
21 generate_cid,
22 make_gen_type_byte_code,
23 generate_cid_array,
24 generate_cid_init,
25 generate_gen_type_il,
26 generate_expanded_creation,
27 generate_expanded_initialization,
28 instantiation_in,
29 generic_derivation,
30 is_generated_as_single_type
31 end
32
33 SHARED_IL_CASING
34 export
35 {NONE} all
36 end
37
38 SHARED_GENERATION
39 export
40 {NONE} all
41 end
42
43 SHARED_DECLARATIONS
44 export
45 {NONE} all
46 end
47
48 create
49 make
50
51 feature {NONE} -- Initialization
52
53 make (id: INTEGER) is
54 -- Create new instance of `Current' with `class_id'
55 -- assigned with `id'.
56 require
57 valid_id: id > 0
58 do
59 class_id := id
60 if is_basic then
61 -- We know for sure that it is expanded then.
62 is_expanded := True
63 end
64 ensure
65 class_id_set: class_id = id
66 end
67
68 feature -- Access
69
70 class_id: INTEGER
71 -- Base class id of the type class
72
73 meta_generic: META_GENERIC is
74 -- Meta generic array describing the type class
75 do
76 -- No meta generic in non-generic type
77 end
78
79 cr_info : CREATE_INFO
80 -- Additional information for the creation
81 -- of generic types with anchored parameters
82
83 true_generics : ARRAY [TYPE_I] is
84 -- Array of generics: no mapping reference -> REFERENCE_I
85 do
86 -- Non generic types don't have them
87 end
88
89 base_class: CLASS_C is
90 -- Base class associated to the class type
91 do
92 Result := System.class_of_id (class_id)
93 end
94
95 generic_derivation: CL_TYPE_I is
96 -- Precise generic derivation of current type.
97 -- That is to say given a type, it gives the associated TYPE_I
98 -- which can be used to search its associated CLASS_TYPE.
99 do
100 Result := Current
101 end
102
103 type_a: CL_TYPE_A is
104 do
105 create Result.make (class_id)
106 Result.set_is_expanded (is_expanded)
107 Result.set_is_separate (is_separate)
108 end
109
110 name: STRING is
111 -- String that should be displayed in debugger to represent `Current'.
112 do
113 Result := base_name
114 end
115
116 instantiation_in (other: CLASS_TYPE): CL_TYPE_I is
117 -- Instantation of Current in `other'
118 do
119 Result := Current
120 end
121
122 il_type_name (a_prefix: STRING): STRING is
123 -- Class name of current type.
124 local
125 l_class_c: like base_class
126 l_is_precompiled: BOOLEAN
127 l_cl_type: like associated_class_type
128 do
129 l_class_c := base_class
130 if is_external then
131 Result := l_class_c.external_class_name.twin
132 else
133 l_is_precompiled := l_class_c.is_precompiled
134 if l_is_precompiled then
135 l_cl_type := associated_class_type
136 l_is_precompiled := l_cl_type.is_precompiled
137 if l_is_precompiled then
138 Result := associated_class_type.il_type_name (a_prefix)
139 end
140 end
141 if not l_is_precompiled then
142 Result := internal_il_type_name (l_class_c.name.twin, a_prefix)
143 end
144 end
145 end
146
147 description: ATTR_DESC is
148 -- Type description for skeletons
149 local
150 exp: EXPANDED_DESC
151 ref: REFERENCE_DESC
152 do
153 if is_expanded then
154 create exp
155 exp.set_cl_type_i (Current)
156 exp.set_type_i (Current)
157 Result := exp
158 else
159 Result := c_type.description
160 ref ?= Result
161 if ref /= Void then
162 ref.set_type_i (Current)
163 end
164 end
165 end
166
167 c_type: TYPE_C is
168 -- Associated C type
169 do
170 Result := Reference_c_type
171 end
172
173 reference_type: CL_TYPE_I is
174 -- Associated reference type of Current
175 do
176 if not is_expanded then
177 Result := Current
178 else
179 Result := twin
180 Result.set_is_expanded (False)
181 end
182 end
183
184 associated_reference_class_type: CLASS_TYPE is
185 -- Reference class type of Current
186 do
187 Result := reference_type.associated_class_type
188 end
189
190 associated_class_type: CLASS_TYPE is
191 -- Associated class type
192 require
193 has: has_associated_class_type
194 do
195 Result := base_class.types.search_item (Current)
196 end
197
198 type_id: INTEGER is
199 -- Type id of the correponding class type
200 do
201 Result := associated_class_type.type_id
202 end
203
204 sk_value: INTEGER is
205 -- Generate SK value associated to the current type.
206 do
207 if is_expanded then
208 Result := Sk_exp | (type_id - 1)
209 else
210 Result := Sk_ref | (type_id - 1)
211 end
212 end
213
214 hash_code: INTEGER is
215 -- Hash code for current type
216 do
217 Result := Other_code + class_id
218 end
219
220 feature -- Status
221
222 element_type: INTEGER_8 is
223 -- Void element type
224 do
225 if is_expanded then
226 Result := feature {MD_SIGNATURE_CONSTANTS}.Element_type_valuetype
227 else
228 if class_id = System.system_string_class.compiled_class.class_id then
229 Result := feature {MD_SIGNATURE_CONSTANTS}.Element_type_string
230 elseif class_id = System.system_object_id or class_id = system.any_id then
231 -- For ANY or SYSTEM_OBJECT, we always generate a System.Object
232 -- signature since we can now assign SYSTEM_OBJECTs into ANYs.
233 Result := feature {MD_SIGNATURE_CONSTANTS}.Element_type_object
234 else
235 Result := feature {MD_SIGNATURE_CONSTANTS}.Element_type_class
236 end
237 end
238 end
239
240 tuple_code: INTEGER_8 is
241 -- Tuple code for class type
242 do
243 Result := feature {SHARED_GEN_CONF_LEVEL}.reference_tuple_code
244 end
245
246 is_expanded: BOOLEAN
247 -- Is the type expanded?
248
249 is_separate: BOOLEAN
250 -- Is the type separate?
251
252 is_enum: BOOLEAN is
253 -- Is current type an IL enum type?
254 -- Useful to find out if some call optimization can be done
255 -- in FEATURE_B.
256 require
257 il_generation: System.il_generation
258 do
259 Result := is_expanded and then base_class.is_enum
260 end
261
262 is_external: BOOLEAN is
263 -- Is current type based on an external class?
264 local
265 l_base_class: like base_class
266 do
267 -- All Eiffel basic types are externals, and only basic types used
268 -- as reference are not external.
269 l_base_class := base_class
270 Result := is_basic or (not l_base_class.is_basic and l_base_class.is_external)
271 end
272
273 is_generated_as_single_type: BOOLEAN is
274 -- Is associated type generated as a single type or as an interface type and
275 -- an implementation type.
276 do
277 -- External classes have only one type.
278 Result := is_external
279 if not Result then
280 -- Classes that inherits from external classes
281 -- have only one generated type.
282 Result := base_class.is_single
283 end
284 end
285
286 is_valid: BOOLEAN is
287 -- Is the base class still in the system and matches its specification?
288 local
289 l_base_class: like base_class
290 do
291 l_base_class := base_class
292 Result := l_base_class /= Void and then (l_base_class.generics = Void)
293 end
294
295 is_reference: BOOLEAN is
296 -- Is the type a reference type ?
297 do
298 Result := not is_expanded
299 end;
300
301 is_explicit: BOOLEAN is
302 -- Is Current type fixed at compile time?
303 do
304 if cr_info /= Void then
305 Result := cr_info.is_explicit
306 else
307 Result := True
308 end
309 end
310
311 has_associated_class_type: BOOLEAN is
312 -- Has `Current' an associated class type?
313 do
314 Result := base_class.types.has_type (Current)
315 end
316
317 same_as (other: TYPE_I): BOOLEAN is
318 -- Is `other' equal to Current ?
319 local
320 other_cl_type: CL_TYPE_I
321 do
322 other_cl_type ?= other
323 Result := other_cl_type /= Void -- FIXME
324 and then other_cl_type.class_id = class_id
325 and then other_cl_type.is_expanded = is_expanded
326 and then other_cl_type.is_separate = is_separate
327 and then other_cl_type.meta_generic = Void
328 and then other_cl_type.true_generics = Void
329 end
330
331 feature -- Setting
332
333 set_is_expanded (b: BOOLEAN) is
334 -- Assign `b' to `is_expanded'.
335 do
336 is_expanded := b
337 ensure
338 is_expanded_set: is_expanded = b
339 end
340
341 set_is_separate (b: BOOLEAN) is
342 -- Assign `b' to `is_separate'.
343 do
344 is_separate := b
345 ensure
346 is_separate_set: is_separate = b
347 end
348
349 set_cr_info (cinfo : CREATE_INFO) is
350 -- Set `cr_info' to `cinfo'.
351 require
352 create_info_not_void: cinfo /= Void
353 not_expanded: not is_expanded
354 do
355 cr_info := cinfo
356 ensure
357 cr_info_set : cr_info = cinfo
358 end
359
360 feature -- C generation
361
362 generate_expanded_creation (buffer: GENERATION_BUFFER; target_name: STRING) is
363 -- Generate creation of expanded object associated to Current.
364 do
365 associated_class_type.generate_expanded_creation (buffer, target_name)
366 end
367
368 generate_expanded_initialization (buffer: GENERATION_BUFFER; target_name: STRING) is
369 -- Generate creation of expanded object associated to Current.
370 do
371 associated_class_type.generate_expanded_initialization (buffer, target_name, target_name, True)
372 end
373
374 generate_cecil_value (buffer: GENERATION_BUFFER) is
375 -- Generate cecil value
376 do
377 if not is_expanded then
378 buffer.put_string ("SK_REF + (uint32) ")
379 else
380 buffer.put_string ("SK_EXP + (uint32) ")
381 end
382 buffer.put_type_id (associated_class_type.type_id)
383 end
384
385 feature -- Array optimization
386
387 conforms_to_array: BOOLEAN is
388 do
389 Result := base_class.conform_to (array_class_c)
390 end
391
392 feature {NONE} -- Array optimization
393
394 array_class_c: CLASS_C is
395 once
396 Result := System.array_class.compiled_class
397 end
398
399 feature -- Generic conformance
400
401 generated_id (final_mode : BOOLEAN) : INTEGER is
402
403 do
404 if final_mode then
405 Result := type_id - 1
406 else
407 Result := associated_class_type.static_type_id - 1
408 end
409 end
410
411 generate_cid (buffer : GENERATION_BUFFER; final_mode, use_info : BOOLEAN) is
412
413 do
414 if
415 use_info and then (cr_info /= Void)
416 and then not is_expanded
417 then
418 -- It's an anchored type
419 cr_info.generate_cid (buffer, final_mode)
420 else
421 buffer.put_integer (generated_id (final_mode))
422 buffer.put_character (',')
423 end
424 end
425
426 make_gen_type_byte_code (ba : BYTE_ARRAY; use_info : BOOLEAN) is
427 do
428 if
429 use_info and then (cr_info /= Void)
430 and then not is_expanded
431 then
432 -- It's an anchored type
433 cr_info.make_gen_type_byte_code (ba)
434 else
435 ba.append_short_integer (generated_id (False))
436 end
437 end
438
439 generate_cid_array (buffer : GENERATION_BUFFER;
440 final_mode, use_info : BOOLEAN; idx_cnt : COUNTER) is
441 local
442 dummy : INTEGER
443 do
444 if
445 use_info and then (cr_info /= Void)
446 and then not is_expanded
447 then
448 -- It's an anchored type
449 cr_info.generate_cid_array (buffer, final_mode, idx_cnt)
450 else
451 buffer.put_integer (generated_id (final_mode))
452 buffer.put_character (',')
453
454 -- Increment counter
455 dummy := idx_cnt.next
456 end
457 end
458
459 generate_cid_init (buffer : GENERATION_BUFFER;
460 final_mode, use_info : BOOLEAN; idx_cnt : COUNTER) is
461 local
462 dummy : INTEGER
463 do
464 if
465 use_info and then (cr_info /= Void)
466 and then not is_expanded
467 then
468 -- It's an anchored type
469 cr_info.generate_cid_init (buffer, final_mode, idx_cnt)
470 else
471 dummy := idx_cnt.next
472 end
473 end
474
475 feature -- Generic conformance for IL
476
477 generate_gen_type_il (il_generator: IL_CODE_GENERATOR; use_info : BOOLEAN) is
478 -- `use_info' is true iff we generate code for a
479 -- creation instruction.
480 do
481 if use_info and then cr_info /= Void then
482 -- It's an anchored type, we call feature
483 -- that will tell us the real type of the
484 -- anchor in the context of Current.
485 cr_info.generate_il_type
486 else
487 il_generator.generate_class_type_instance (Current)
488 end
489 end
490
491 feature {NONE} -- Implementation
492
493 base_name: STRING is
494 -- String that should be displayed in debugger to represent `Current'.
495 local
496 l_base_class: like base_class
497 do
498 create Result.make (32)
499 l_base_class := base_class
500 if is_expanded and not l_base_class.is_expanded then
501 Result.append ("expanded ")
502 elseif not is_expanded and l_base_class.is_expanded then
503 Result.append ("reference ")
504 elseif is_separate then
505 Result.append ("separate ")
506 end
507 Result.append (l_base_class.name)
508 end
509
510 frozen internal_il_type_name (a_base_name, a_prefix: STRING): STRING is
511 -- Full type name of `a_base_name' using `a_prefix' in IL code generation
512 -- with namespace specification
513 require
514 a_base_name_not_void: a_base_name /= Void
515 local
516 l_name: STRING
517 l_base_class: like base_class
518 do
519 l_base_class := base_class
520 -- Result needs to be in lower case because that's
521 -- what our casing conversion routines require to perform
522 -- a good job.
523 if
524 (is_expanded and l_base_class.is_expanded) or
525 (not is_expanded and not l_base_class.is_expanded)
526 then
527 Result := a_base_name.as_lower
528 else
529 if is_expanded then
530 create Result.make (6 + a_base_name.count)
531 Result.append ("VALUE_")
532 else
533 create Result.make (10 + a_base_name.count)
534 Result.append ("REFERENCE_")
535 end
536 Result.append (a_base_name)
537 Result.to_lower
538 end
539 l_name := l_base_class.lace_class.actual_namespace
540 if a_prefix /= Void then
541 if l_name.is_empty then
542 l_name := a_prefix + "."
543 else
544 l_name := il_casing.namespace_casing (System.dotnet_naming_convention,
545 l_name) + "." + a_prefix + "."
546 end
547 else
548 if not l_name.is_empty then
549 l_name := il_casing.namespace_casing (System.dotnet_naming_convention,
550 l_name) + "."
551 end
552 end
553 Result := l_name + il_casing.pascal_casing (System.dotnet_naming_convention,
554 Result, feature {IL_CASING_CONVERSION}.upper_case)
555 ensure
556 internal_il_type_name_not_void: Result /= Void
557 internal_il_type_name_not_empty: not Result.is_empty
558 end
559
560 invariant
561 class_id_positive: class_id > 0
562
563 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date Id Revision

  ViewVC Help
Powered by ViewVC 1.1.23