/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 93443 - (show annotations)
Tue Nov 19 21:46:04 2013 UTC (6 years ago) by zurfluhs
File size: 7658 byte(s)
Code Analysis: added 'nested loops/branches' rule
1 note
2 description: "Summary description for {CA_CODE_ANALYZER}."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit {NONE}
11 SHARED_EIFFEL_PROJECT
12 CA_SHARED_NAMES
13
14 create
15 make
16
17 feature {NONE} -- Initialization
18
19 make
20 -- Initialization for `Current'.
21 do
22 create settings
23 create rules.make
24 -- Adding example rules
25 rules.extend (create {CA_SELF_ASSIGNMENT_RULE}.make)
26 rules.extend (create {CA_UNUSED_ARGUMENT_RULE}.make)
27 rules.extend (create {CA_NPATH_RULE}.make)
28 rules.extend (create {CA_EMPTY_IF_RULE}.make)
29 rules.extend (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
30 rules.extend (create {CA_CQ_SEPARATION_RULE}.make)
31 rules.extend (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
32 rules.extend (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make)
33 rules.extend (create {CA_NESTED_COMPLEXITY_RULE}.make)
34
35 -- Issues (contract violations, exceptions) with {EPA_CFG_BUILDER} and
36 -- classes from library 'program_analysis' in general.
37 -- rules.extend (create {CA_VARIABLE_NOT_READ_RULE}.make)
38
39 create classes_to_analyze.make
40 create rule_violations.make (100)
41 create completed_actions
42
43 create ignoredby.make (25)
44 create library_class.make (25)
45 create nonlibrary_class.make (25)
46 end
47
48 feature -- Analysis interface
49
50 add_completed_action (a_action: PROCEDURE [ANY, TUPLE [BOOLEAN] ])
51 do
52 completed_actions.extend (a_action)
53 end
54
55 analyze
56 require
57 not is_running
58 local
59 l_rules_checker: CA_ALL_RULES_CHECKER
60 l_task: CA_RULE_CHECKING_TASK
61 do
62 is_running := True
63 -- TODO: caching
64 rule_violations.wipe_out
65
66 create l_rules_checker.make
67 across rules as l_rules loop
68 l_rules.item.clear_violations
69 if l_rules.item.is_enabled then -- important: only add enabled rules
70 if system_wide_check or else (not l_rules.item.is_system_wide) then
71 -- do not add system wide rules if we check only parts of the system
72 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
73
74 l_std_rule.prepare_checking (l_rules_checker)
75 -- TODO: prepare rules of other types?
76 end
77 end
78 end
79 end
80
81 create l_task.make (l_rules_checker, rules, classes_to_analyze, agent analysis_completed)
82 rota.run_task (l_task)
83 end
84
85 clear_classes_to_analyze
86 do
87 classes_to_analyze.wipe_out
88 end
89
90 add_whole_system
91 local
92 l_groups: LIST [CONF_GROUP]
93 l_cluster: CLUSTER_I
94 do
95 from
96 l_groups := eiffel_universe.groups
97 l_groups.start
98 until
99 l_groups.after
100 loop
101 l_cluster ?= l_groups.item_for_iteration
102 -- Only load top-level clusters, as they are loaded recursively afterwards
103 if l_cluster /= Void and then l_cluster.parent_cluster = Void then
104 add_cluster (l_cluster)
105 end
106 l_groups.forth
107 end
108
109 system_wide_check := True
110 end
111
112 add_cluster (a_cluster: CLUSTER_I)
113 local
114 l_conf_class: CONF_CLASS
115 l_class_i: CLASS_I
116 do
117 system_wide_check := False
118
119 from
120 a_cluster.classes.start
121 until
122 a_cluster.classes.after
123 loop
124 l_conf_class := a_cluster.classes.item_for_iteration
125 l_class_i := eiffel_universe.class_named (l_conf_class.name, a_cluster)
126 add_class (l_class_i)
127 a_cluster.classes.forth
128 end
129 if a_cluster.sub_clusters /= Void then
130 from
131 a_cluster.sub_clusters.start
132 until
133 a_cluster.sub_clusters.after
134 loop
135 add_cluster (a_cluster.sub_clusters.item_for_iteration)
136 a_cluster.sub_clusters.forth
137 end
138 end
139 end
140
141 add_group (a_group: CONF_GROUP)
142 require
143 a_group_not_void: a_group /= Void
144 local
145 l_conf_class: CONF_CLASS
146 l_class_i: CLASS_I
147 do
148 from
149 a_group.classes.start
150 until
151 a_group.classes.after
152 loop
153 l_conf_class := a_group.classes.item_for_iteration
154 l_class_i := eiffel_universe.class_named (l_conf_class.name, a_group)
155 add_class (l_class_i)
156 a_group.classes.forth
157 end
158 end
159
160 add_classes (a_classes: ITERABLE[CLASS_I])
161 do
162 system_wide_check := False
163
164 across a_classes as l_classes loop
165 add_class (l_classes.item)
166 end
167 end
168
169 add_class (a_class: CLASS_I)
170 local
171 l_class_c: CLASS_C
172 do
173 system_wide_check := False
174
175 if a_class.is_compiled then
176 l_class_c := a_class.compiled_class
177 check l_class_c /= Void end
178 classes_to_analyze.extend (l_class_c)
179
180 extract_indexes (l_class_c)
181 else
182 print ("Class " + a_class.name + " not compiled (skipped).%N")
183 end
184 end
185
186 feature -- Properties
187
188 is_running: BOOLEAN
189
190 analysis_successful: BOOLEAN
191
192 rules: LINKED_LIST[CA_RULE]
193
194 rule_violations: detachable HASH_TABLE[SORTED_TWO_WAY_LIST[CA_RULE_VIOLATION], CLASS_C]
195
196 feature {NONE} -- Implementation
197
198 analysis_completed
199 do
200 across classes_to_analyze as l_classes loop
201 rule_violations.extend (create {SORTED_TWO_WAY_LIST[CA_RULE_VIOLATION]}.make, l_classes.item)
202 end
203
204 across rules as l_rules loop
205 across l_rules.item.violations as l_v loop
206 -- check the ignore list
207 if is_violation_valid (l_v.item) then
208 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
209 end
210 end
211 end
212
213 clear_classes_to_analyze
214
215 is_running := False
216 completed_actions.call ([True])
217 completed_actions.wipe_out
218 end
219
220 is_violation_valid (a_viol: CA_RULE_VIOLATION): BOOLEAN
221 local
222 l_affected_class: CLASS_C
223 l_rule: CA_RULE
224 do
225 l_affected_class := a_viol.affected_class
226 l_rule := a_viol.rule
227
228 Result := True
229
230 if (ignoredby.has (l_affected_class))
231 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
232 Result := False
233 end
234
235 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) = True then
236 Result := False
237 end
238
239 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) = True then
240 Result := False
241 end
242 end
243
244 settings: CA_SETTINGS
245
246 classes_to_analyze: LINKED_SET [CLASS_C]
247
248 system_wide_check: BOOLEAN
249
250 completed_actions: ACTION_SEQUENCE [TUPLE [BOOLEAN]]
251
252 frozen rota: detachable ROTA_S
253 -- Access to rota service
254 local
255 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
256 do
257 create l_service_consumer
258 if l_service_consumer.is_service_available and then l_service_consumer.service.is_interface_usable then
259 Result := l_service_consumer.service
260 end
261 end
262
263
264 feature {NONE} -- Class-wide Options (From Indexing Clauses)
265
266 extract_indexes (a_class: CLASS_C)
267 local
268 l_ast: CLASS_AS
269 l_item: STRING_32
270 l_ignoredby: LINKED_LIST [STRING_32]
271 do
272 create l_ignoredby.make
273 l_ignoredby.compare_objects
274 library_class.force (False, a_class)
275 nonlibrary_class.force (False, a_class)
276 l_ast := a_class.ast
277
278 across l_ast.internal_top_indexes as l_indexes loop
279
280 if l_indexes.item.tag.name_32.is_equal ("ca_ignoredby") then
281 across l_indexes.item.index_list as l_list loop
282 l_item := l_list.item.string_value_32
283 l_item.prune_all ('%"')
284 l_ignoredby.extend (l_item)
285 end
286 elseif l_indexes.item.tag.name_32.is_equal ("ca_library") then
287 if not l_indexes.item.index_list.is_empty then
288 l_item := l_indexes.item.index_list.first.string_value_32
289 l_item.to_lower
290 l_item.prune_all ('%"')
291 if l_item.is_equal ("true") then
292 library_class.force (True, a_class)
293 elseif l_item.is_equal ("false") then
294 nonlibrary_class.force (True, a_class)
295 end
296 end
297 end
298 end
299
300 ignoredby.force (l_ignoredby, a_class)
301 end
302
303 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
304
305 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
306
307 invariant
308 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
309
310 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23