/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 93963 - (show annotations)
Sun Jan 12 19:50:44 2014 UTC (6 years ago) by zurfluhs
File size: 11155 byte(s)
Code Analysis: comments and some refactoring.
1 note
2 description: "THE Code Analyzer."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit {NONE}
11 SHARED_EIFFEL_PROJECT
12 CA_SHARED_NAMES
13
14 create
15 make
16
17 feature {NONE} -- Initialization
18
19 make
20 -- Initialization for `Current'.
21 do
22 create settings.make
23 create rules.make
24 -- Adding the rules.
25 rules.extend (create {CA_SELF_ASSIGNMENT_RULE}.make)
26 rules.extend (create {CA_UNUSED_ARGUMENT_RULE}.make)
27 rules.extend (create {CA_NPATH_RULE}.make (settings.preference_manager))
28 rules.extend (create {CA_EMPTY_IF_RULE}.make)
29 rules.extend (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
30 rules.extend (create {CA_CQ_SEPARATION_RULE}.make)
31 rules.extend (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
32 rules.extend (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make)
33 rules.extend (create {CA_NESTED_COMPLEXITY_RULE}.make (settings.preference_manager))
34 rules.extend (create {CA_MANY_ARGUMENTS_RULE}.make (settings.preference_manager))
35 rules.extend (create {CA_CREATION_PROC_EXPORTED_RULE}.make)
36 rules.extend (create {CA_VARIABLE_NOT_READ_RULE}.make)
37 rules.extend (create {CA_SEMICOLON_ARGUMENTS_RULE}.make)
38 rules.extend (create {CA_VERY_LONG_ROUTINE_RULE}.make (settings.preference_manager))
39 rules.extend (create {CA_VERY_BIG_CLASS_RULE}.make (settings.preference_manager))
40 rules.extend (create {CA_FEATURE_SECTION_COMMENT_RULE}.make)
41 rules.extend (create {CA_FEATURE_NOT_COMMENTED_RULE}.make)
42 rules.extend (create {CA_BOOLEAN_RESULT_RULE}.make)
43 rules.extend (create {CA_BOOLEAN_COMPARISON_RULE}.make)
44 rules.extend (create {CA_VERY_SHORT_IDENTIFIER_RULE}.make (settings.preference_manager))
45 rules.extend (create {CA_VERY_LONG_IDENTIFIER_RULE}.make (settings.preference_manager))
46 rules.extend (create {CA_MISSING_IS_EQUAL_RULE}.make)
47 rules.extend (create {CA_SIMPLIFIABLE_BOOLEAN_RULE}.make)
48 rules.extend (create {CA_SELF_COMPARISON_RULE}.make)
49 rules.extend (create {CA_TODO_RULE}.make)
50 rules.extend (create {CA_WRONG_LOOP_ITERATION_RULE}.make)
51 rules.extend (create {CA_INSPECT_INSTRUCTIONS_RULE}.make (settings.preference_manager))
52 rules.extend (create {CA_ATTRIBUTE_TO_LOCAL_RULE}.make)
53 rules.extend (create {CA_EMPTY_EFFECTIVE_ROUTINE_RULE}.make)
54 rules.extend (create {CA_IF_ELSE_NOT_EQUAL_RULE}.make)
55 rules.extend (create {CA_SHORT_CIRCUIT_IF_RULE}.make)
56 rules.extend (create {CA_ITERABLE_LOOP_RULE}.make)
57 rules.extend (create {CA_COUNT_EQUALS_ZERO_RULE}.make)
58 rules.extend (create {CA_DEEPLY_NESTED_IF_RULE}.make (settings.preference_manager))
59 rules.extend (create {CA_UNNEEDED_HELPER_VARIABLE_RULE}.make (settings.preference_manager))
60 rules.extend (create {CA_UNNEEDED_PARENTHESES_RULE}.make)
61
62 settings.initialize_rule_settings (rules)
63
64 create classes_to_analyze.make
65 create rule_violations.make (100)
66 create completed_actions
67
68 create ignoredby.make (25)
69 create library_class.make (25)
70 create nonlibrary_class.make (25)
71 end
72
73 feature -- Analysis interface
74
75 add_completed_action (a_action: PROCEDURE [ANY, TUPLE [BOOLEAN]])
76 -- Adds `a_action' to the list of procedures that will be
77 -- called when analysis has completed.
78 do
79 completed_actions.extend (a_action)
80 end
81
82 analyze
83 -- Analyze all the classes that have been added.
84 require
85 not is_running
86 local
87 l_rules_checker: CA_ALL_RULES_CHECKER
88 l_task: CA_RULE_CHECKING_TASK
89 do
90 is_running := True
91
92 create l_rules_checker.make
93 across rules as l_rules loop
94 l_rules.item.clear_violations
95 if l_rules.item.is_enabled.value then -- Important: only add enabled rules.
96 if system_wide_check or else (not l_rules.item.is_system_wide) then
97 -- Do not add system wide rules if we check only parts of the system.
98 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
99
100 l_std_rule.prepare_checking (l_rules_checker)
101 -- TODO: prepare rules of other types?
102 end
103 end
104 end
105 end
106
107 create l_task.make (l_rules_checker, rules, classes_to_analyze, agent analysis_completed)
108 rota.run_task (l_task)
109 end
110
111 clear_classes_to_analyze
112 -- Remove all classes that have been added to the list of classes
113 -- to analyze.
114 do
115 classes_to_analyze.wipe_out
116 end
117
118 add_whole_system
119 -- Add all the classes that are part of the current system. Classes of references libraries
120 -- will not be added.
121 local
122 l_groups: LIST [CONF_GROUP]
123 l_cluster: CLUSTER_I
124 do
125 from
126 l_groups := eiffel_universe.groups
127 l_groups.start
128 until
129 l_groups.after
130 loop
131 l_cluster ?= l_groups.item_for_iteration
132 -- Only load top-level clusters, as the others will be loaded recursively afterwards.
133 if l_cluster /= Void and then l_cluster.parent_cluster = Void then
134 add_cluster (l_cluster)
135 end
136 l_groups.forth
137 end
138
139 system_wide_check := True
140 end
141
142 add_cluster (a_cluster: CLUSTER_I)
143 -- Add all classes of cluster `a_cluster'.
144 local
145 l_conf_class: CONF_CLASS
146 l_class_i: CLASS_I
147 do
148 system_wide_check := False
149
150 from
151 a_cluster.classes.start
152 until
153 a_cluster.classes.after
154 loop
155 l_conf_class := a_cluster.classes.item_for_iteration
156 l_class_i := eiffel_universe.class_named (l_conf_class.name, a_cluster)
157 add_class (l_class_i)
158 a_cluster.classes.forth
159 end
160 if a_cluster.sub_clusters /= Void then
161 from
162 a_cluster.sub_clusters.start
163 until
164 a_cluster.sub_clusters.after
165 loop
166 add_cluster (a_cluster.sub_clusters.item_for_iteration)
167 a_cluster.sub_clusters.forth
168 end
169 end
170 end
171
172 add_group (a_group: CONF_GROUP)
173 -- Add all classes of the configuration group `a_group'.
174 require
175 a_group_not_void: a_group /= Void
176 local
177 l_conf_class: CONF_CLASS
178 l_class_i: CLASS_I
179 do
180 from
181 a_group.classes.start
182 until
183 a_group.classes.after
184 loop
185 l_conf_class := a_group.classes.item_for_iteration
186 l_class_i := eiffel_universe.class_named (l_conf_class.name, a_group)
187 add_class (l_class_i)
188 a_group.classes.forth
189 end
190 end
191
192 add_classes (a_classes: ITERABLE [CLASS_I])
193 -- Add the classes `a_classes'.
194 do
195 system_wide_check := False
196
197 across a_classes as l_classes loop
198 add_class (l_classes.item)
199 end
200 end
201
202 add_class (a_class: CLASS_I)
203 -- Adds class `a_class'.
204 local
205 l_class_c: CLASS_C
206 do
207 system_wide_check := False
208
209 if a_class.is_compiled then
210 l_class_c := a_class.compiled_class
211 check l_class_c /= Void end
212 classes_to_analyze.extend (l_class_c)
213
214 extract_indexes (l_class_c)
215 else
216 print ("Class " + a_class.name + " not compiled (skipped).%N")
217 end
218 end
219
220 feature -- Properties
221
222 is_running: BOOLEAN
223 -- Is code analysis running?
224
225 rules: LINKED_LIST [CA_RULE]
226 -- List of rules that will be used for analysis.
227
228 rule_violations: detachable HASH_TABLE [SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION], CLASS_C]
229 -- All found violations from the last analysis.
230
231 preferences: PREFERENCES
232 -- Code Analysis preferences.
233 do Result := settings.preferences end
234
235 class_list: ITERABLE [CLASS_C]
236 -- List of classes that have been added.
237 do Result := classes_to_analyze end
238
239 feature {NONE} -- Implementation
240
241 analysis_completed
242 -- Will be called when the analysis task has finished.
243 do
244 across rules as l_rules loop
245 across l_rules.item.violations as l_v loop
246 -- Check the ignore list.
247 if is_violation_valid (l_v.item) then
248 -- Make sure a list for this class exists in the hash table:
249 rule_violations.put (create {SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION]}.make, l_v.item.affected_class)
250 -- Add the violation.
251 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
252 end
253 end
254 end
255
256 clear_classes_to_analyze
257
258 is_running := False
259 completed_actions.call ([True])
260 completed_actions.wipe_out
261 end
262
263 is_violation_valid (a_viol: CA_RULE_VIOLATION): BOOLEAN
264 -- Is the violation `a_viol' valid under the current settings
265 -- such as the rule ignore list of a class, or the library or
266 -- non-library status of a class?
267 local
268 l_affected_class: CLASS_C
269 l_rule: CA_RULE
270 do
271 l_affected_class := a_viol.affected_class
272 l_rule := a_viol.rule
273
274 Result := True
275
276 if (ignoredby.has (l_affected_class))
277 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
278 Result := False
279 end
280
281 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) = True then
282 Result := False
283 end
284
285 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) = True then
286 Result := False
287 end
288 end
289
290 settings: CA_SETTINGS
291 -- The settings manager for Code Analysis.
292
293 classes_to_analyze: LINKED_SET [CLASS_C]
294 -- List of classes that shall be analyzed.
295
296 system_wide_check: BOOLEAN
297 -- Shall the whole system be analyzed?
298
299 completed_actions: ACTION_SEQUENCE [TUPLE [BOOLEAN]]
300 -- List of procedure to call when analysis has completed.
301
302 frozen rota: detachable ROTA_S
303 -- Accesses the rota service.
304 local
305 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
306 do
307 create l_service_consumer
308 if l_service_consumer.is_service_available and then l_service_consumer.service.is_interface_usable then
309 Result := l_service_consumer.service
310 end
311 end
312
313
314 feature {NONE} -- Class-wide Options (From Indexing Clauses)
315
316 extract_indexes (a_class: CLASS_C)
317 -- Extracts options from the indexing clause of class `a_class'.
318 local
319 l_ast: CLASS_AS
320 l_item: STRING_32
321 l_ignoredby: LINKED_LIST [STRING_32]
322 do
323 create l_ignoredby.make
324 l_ignoredby.compare_objects -- We want to compare the actual strings.
325 -- Reset the class flags.
326 library_class.force (False, a_class)
327 nonlibrary_class.force (False, a_class)
328 l_ast := a_class.ast
329
330 if attached l_ast.internal_top_indexes then
331 across l_ast.internal_top_indexes as l_indexes loop
332
333 if l_indexes.item.tag.name_32.is_equal ("ca_ignoredby") then
334 -- Class wants to ignore certain rules.
335 across l_indexes.item.index_list as l_list loop
336 l_item := l_list.item.string_value_32
337 l_item.prune_all ('%"')
338 l_ignoredby.extend (l_item)
339 end
340 elseif l_indexes.item.tag.name_32.is_equal ("ca_library") then
341 -- Class has information on whether it is a library class.
342 if not l_indexes.item.index_list.is_empty then
343 l_item := l_indexes.item.index_list.first.string_value_32
344 l_item.to_lower
345 l_item.prune_all ('%"')
346 if l_item.is_equal ("true") then
347 library_class.force (True, a_class)
348 elseif l_item.is_equal ("false") then
349 nonlibrary_class.force (True, a_class)
350 end
351 end
352 end
353 end
354 end
355
356 ignoredby.force (l_ignoredby, a_class)
357 end
358
359 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
360 -- Maps classes to lists of rules (rule IDs) the class wants to be ignored by.
361
362 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
363 -- Stores classes that are marked as library or non-library classes.
364
365 invariant
366 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
367
368 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23