/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 94106 - (show annotations)
Tue Jan 28 15:49:22 2014 UTC (5 years, 11 months ago) by zurfluhs
File size: 12089 byte(s)
Code Analysis: logging functionality
1 note
2 description: "THE Code Analyzer."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit {NONE}
11 SHARED_EIFFEL_PROJECT
12 CA_SHARED_NAMES
13
14 create
15 make
16
17 feature {NONE} -- Initialization
18
19 make
20 -- Initialization for `Current'.
21 do
22 create settings.make
23 create rules.make
24 -- Adding the rules.
25 rules.extend (create {CA_SELF_ASSIGNMENT_RULE}.make)
26 rules.extend (create {CA_UNUSED_ARGUMENT_RULE}.make)
27 rules.extend (create {CA_NPATH_RULE}.make (settings.preference_manager))
28 rules.extend (create {CA_EMPTY_IF_RULE}.make)
29 rules.extend (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
30 rules.extend (create {CA_CQ_SEPARATION_RULE}.make)
31 rules.extend (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
32 rules.extend (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make)
33 rules.extend (create {CA_NESTED_COMPLEXITY_RULE}.make (settings.preference_manager))
34 rules.extend (create {CA_MANY_ARGUMENTS_RULE}.make (settings.preference_manager))
35 rules.extend (create {CA_CREATION_PROC_EXPORTED_RULE}.make)
36 rules.extend (create {CA_VARIABLE_NOT_READ_RULE}.make)
37 rules.extend (create {CA_SEMICOLON_ARGUMENTS_RULE}.make)
38 rules.extend (create {CA_VERY_LONG_ROUTINE_RULE}.make (settings.preference_manager))
39 rules.extend (create {CA_VERY_BIG_CLASS_RULE}.make (settings.preference_manager))
40 rules.extend (create {CA_FEATURE_SECTION_COMMENT_RULE}.make)
41 rules.extend (create {CA_FEATURE_NOT_COMMENTED_RULE}.make)
42 rules.extend (create {CA_BOOLEAN_RESULT_RULE}.make)
43 rules.extend (create {CA_BOOLEAN_COMPARISON_RULE}.make)
44 rules.extend (create {CA_VERY_SHORT_IDENTIFIER_RULE}.make (settings.preference_manager))
45 rules.extend (create {CA_VERY_LONG_IDENTIFIER_RULE}.make (settings.preference_manager))
46 rules.extend (create {CA_MISSING_IS_EQUAL_RULE}.make)
47 rules.extend (create {CA_SIMPLIFIABLE_BOOLEAN_RULE}.make)
48 rules.extend (create {CA_SELF_COMPARISON_RULE}.make)
49 rules.extend (create {CA_TODO_RULE}.make)
50 rules.extend (create {CA_WRONG_LOOP_ITERATION_RULE}.make)
51 rules.extend (create {CA_INSPECT_INSTRUCTIONS_RULE}.make (settings.preference_manager))
52 rules.extend (create {CA_ATTRIBUTE_TO_LOCAL_RULE}.make)
53 rules.extend (create {CA_EMPTY_EFFECTIVE_ROUTINE_RULE}.make)
54 rules.extend (create {CA_IF_ELSE_NOT_EQUAL_RULE}.make)
55 rules.extend (create {CA_SHORT_CIRCUIT_IF_RULE}.make)
56 rules.extend (create {CA_ITERABLE_LOOP_RULE}.make)
57 rules.extend (create {CA_COUNT_EQUALS_ZERO_RULE}.make)
58 rules.extend (create {CA_DEEPLY_NESTED_IF_RULE}.make (settings.preference_manager))
59 rules.extend (create {CA_UNNEEDED_HELPER_VARIABLE_RULE}.make (settings.preference_manager))
60 rules.extend (create {CA_UNNEEDED_PARENTHESES_RULE}.make)
61
62 settings.initialize_rule_settings (rules)
63
64 create classes_to_analyze.make
65 create rule_violations.make (100)
66 create completed_actions
67
68 create ignoredby.make (25)
69 create library_class.make (25)
70 create nonlibrary_class.make (25)
71 end
72
73 feature -- Analysis interface
74
75 add_completed_action (a_action: PROCEDURE [ANY, TUPLE [BOOLEAN]])
76 -- Adds `a_action' to the list of procedures that will be
77 -- called when analysis has completed.
78 do
79 completed_actions.extend (a_action)
80 end
81
82 analyze
83 -- Analyze all the classes that have been added.
84 require
85 not is_running
86 local
87 l_rules_checker: CA_ALL_RULES_CHECKER
88 l_task: CA_RULE_CHECKING_TASK
89 l_rules_to_check: LINKED_LIST [CA_RULE]
90 do
91 is_running := True
92
93 create l_rules_checker.make
94 create l_rules_to_check.make
95 across rules as l_rules loop
96 l_rules.item.clear_violations
97 if is_rule_checkable (l_rules.item) then
98 l_rules_to_check.extend (l_rules.item)
99 -- Here we only prepare standard rules. The rule checking task will iterate again
100 -- through the rules and run the analysis on the enabled rules.
101 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
102 l_std_rule.prepare_checking (l_rules_checker)
103 end
104 end
105 end
106
107 create l_task.make (l_rules_checker, l_rules_to_check, classes_to_analyze, agent analysis_completed)
108 rota.run_task (l_task)
109 end
110
111 is_rule_checkable (a_rule: CA_RULE): BOOLEAN
112 do
113 Result := a_rule.is_enabled.value
114 and then (system_wide_check or else (not a_rule.is_system_wide))
115 and then is_severity_enabled (a_rule.severity)
116 end
117
118 clear_classes_to_analyze
119 -- Remove all classes that have been added to the list of classes
120 -- to analyze.
121 do
122 classes_to_analyze.wipe_out
123 end
124
125 add_whole_system
126 -- Add all the classes that are part of the current system. Classes of references libraries
127 -- will not be added.
128 local
129 l_groups: LIST [CONF_GROUP]
130 l_cluster: CLUSTER_I
131 do
132 from
133 l_groups := eiffel_universe.groups
134 l_groups.start
135 until
136 l_groups.after
137 loop
138 l_cluster ?= l_groups.item_for_iteration
139 -- Only load top-level clusters, as the others will be loaded recursively afterwards.
140 if l_cluster /= Void and then l_cluster.parent_cluster = Void then
141 add_cluster (l_cluster)
142 end
143 l_groups.forth
144 end
145
146 system_wide_check := True
147 end
148
149 add_cluster (a_cluster: CLUSTER_I)
150 -- Add all classes of cluster `a_cluster'.
151 local
152 l_conf_class: CONF_CLASS
153 l_class_i: CLASS_I
154 do
155 system_wide_check := False
156
157 from
158 a_cluster.classes.start
159 until
160 a_cluster.classes.after
161 loop
162 l_conf_class := a_cluster.classes.item_for_iteration
163 l_class_i := eiffel_universe.class_named (l_conf_class.name, a_cluster)
164 add_class (l_class_i)
165 a_cluster.classes.forth
166 end
167 if a_cluster.sub_clusters /= Void then
168 from
169 a_cluster.sub_clusters.start
170 until
171 a_cluster.sub_clusters.after
172 loop
173 add_cluster (a_cluster.sub_clusters.item_for_iteration)
174 a_cluster.sub_clusters.forth
175 end
176 end
177 end
178
179 add_group (a_group: CONF_GROUP)
180 -- Add all classes of the configuration group `a_group'.
181 require
182 a_group_not_void: a_group /= Void
183 local
184 l_conf_class: CONF_CLASS
185 l_class_i: CLASS_I
186 do
187 from
188 a_group.classes.start
189 until
190 a_group.classes.after
191 loop
192 l_conf_class := a_group.classes.item_for_iteration
193 l_class_i := eiffel_universe.class_named (l_conf_class.name, a_group)
194 add_class (l_class_i)
195 a_group.classes.forth
196 end
197 end
198
199 add_classes (a_classes: ITERABLE [CLASS_I])
200 -- Add the classes `a_classes'.
201 do
202 system_wide_check := False
203
204 across a_classes as l_classes loop
205 add_class (l_classes.item)
206 end
207 end
208
209 add_class (a_class: CLASS_I)
210 -- Adds class `a_class'.
211 local
212 l_class_c: CLASS_C
213 do
214 system_wide_check := False
215
216 if a_class.is_compiled then
217 l_class_c := a_class.compiled_class
218 check l_class_c /= Void end
219 classes_to_analyze.extend (l_class_c)
220
221 extract_indexes (l_class_c)
222 else
223 print ("Class " + a_class.name + " not compiled (skipped).%N")
224 end
225 end
226
227 feature -- Properties
228
229 is_running: BOOLEAN
230 -- Is code analysis running?
231
232 rules: LINKED_LIST [CA_RULE]
233 -- List of rules that will be used for analysis.
234
235 rule_violations: detachable HASH_TABLE [SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION], CLASS_C]
236 -- All found violations from the last analysis.
237
238 preferences: PREFERENCES
239 -- Code Analysis preferences.
240 do Result := settings.preferences end
241
242 class_list: ITERABLE [CLASS_C]
243 -- List of classes that have been added.
244 do Result := classes_to_analyze end
245
246 feature {NONE} -- Implementation
247
248 analysis_completed
249 -- Will be called when the analysis task has finished.
250 local
251 l_logger: CA_LOGGER
252 do
253 create l_logger.make ("last_analysis_result.csv")
254 -- CSV title column.
255 l_logger.log ("Severity;Class;Location;Title;Description;Rule ID;Severity Score")
256
257 across rules as l_rules loop
258 across l_rules.item.violations as l_v loop
259 -- Check the ignore list.
260 if is_violation_valid (l_v.item) then
261 -- Make sure a list for this class exists in the hash table:
262 rule_violations.put (create {SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION]}.make, l_v.item.affected_class)
263 -- Add the violation.
264 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
265 -- Log it.
266 l_logger.log (l_v.item.out)
267 end
268 end
269 end
270
271 l_logger.close_log
272
273 clear_classes_to_analyze
274
275 is_running := False
276 completed_actions.call ([True])
277 completed_actions.wipe_out
278 end
279
280 is_violation_valid (a_viol: CA_RULE_VIOLATION): BOOLEAN
281 -- Is the violation `a_viol' valid under the current settings
282 -- such as the rule ignore list of a class, or the library or
283 -- non-library status of a class?
284 local
285 l_affected_class: CLASS_C
286 l_rule: CA_RULE
287 do
288 l_affected_class := a_viol.affected_class
289 l_rule := a_viol.rule
290
291 Result := True
292
293 if ignoredby.has (l_affected_class)
294 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
295 Result := False
296 end
297
298 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) then
299 Result := False
300 end
301
302 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) then
303 Result := False
304 end
305 end
306
307 settings: CA_SETTINGS
308 -- The settings manager for Code Analysis.
309
310 classes_to_analyze: LINKED_SET [CLASS_C]
311 -- List of classes that shall be analyzed.
312
313 system_wide_check: BOOLEAN
314 -- Shall the whole system be analyzed?
315
316 completed_actions: ACTION_SEQUENCE [TUPLE [BOOLEAN]]
317 -- List of procedure to call when analysis has completed.
318
319 frozen rota: detachable ROTA_S
320 -- Accesses the rota service.
321 local
322 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
323 do
324 create l_service_consumer
325 if l_service_consumer.is_service_available and then l_service_consumer.service.is_interface_usable then
326 Result := l_service_consumer.service
327 end
328 end
329
330 is_severity_enabled (a_severity: CA_RULE_SEVERITY): BOOLEAN
331 do
332 Result := (attached {CA_HINT} a_severity and settings.are_hints_enabled.value)
333 or else (attached {CA_SUGGESTION} a_severity and settings.are_suggestions_enabled.value)
334 or else (attached {CA_WARNING} a_severity and settings.are_warnings_enabled.value)
335 or else (attached {CA_ERROR} a_severity and settings.are_errors_enabled.value)
336 end
337
338
339 feature {NONE} -- Class-wide Options (From Indexing Clauses)
340
341 extract_indexes (a_class: CLASS_C)
342 -- Extracts options from the indexing clause of class `a_class'.
343 local
344 l_ast: CLASS_AS
345 l_item: STRING_32
346 l_ignoredby: LINKED_LIST [STRING_32]
347 do
348 create l_ignoredby.make
349 l_ignoredby.compare_objects -- We want to compare the actual strings.
350 -- Reset the class flags.
351 library_class.force (False, a_class)
352 nonlibrary_class.force (False, a_class)
353 l_ast := a_class.ast
354
355 if attached l_ast.internal_top_indexes then
356 across l_ast.internal_top_indexes as l_indexes loop
357
358 if l_indexes.item.tag.name_32.is_equal ("ca_ignoredby") then
359 -- Class wants to ignore certain rules.
360 across l_indexes.item.index_list as l_list loop
361 l_item := l_list.item.string_value_32
362 l_item.prune_all ('%"')
363 l_ignoredby.extend (l_item)
364 end
365 elseif l_indexes.item.tag.name_32.is_equal ("ca_library") then
366 -- Class has information on whether it is a library class.
367 if not l_indexes.item.index_list.is_empty then
368 l_item := l_indexes.item.index_list.first.string_value_32
369 l_item.to_lower
370 l_item.prune_all ('%"')
371 if l_item.is_equal ("true") then
372 library_class.force (True, a_class)
373 elseif l_item.is_equal ("false") then
374 nonlibrary_class.force (True, a_class)
375 end
376 end
377 end
378 end
379 end
380
381 ignoredby.force (l_ignoredby, a_class)
382 end
383
384 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
385 -- Maps classes to lists of rules (rule IDs) the class wants to be ignored by.
386
387 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
388 -- Stores classes that are marked as library or non-library classes.
389
390 invariant
391 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
392
393 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23