/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 94158 - (show annotations)
Mon Feb 3 10:37:52 2014 UTC (5 years, 11 months ago) by zurfluhs
File size: 12839 byte(s)
Code Analysis: changes according to code review

- renamed CA_LOGGER
- using bottom indices
- removed unneeded Result assigns
- CA_RULE hash code from id
- renamed CA_RULE_VIOLATION.out
1 note
2 description: "THE Code Analyzer."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit
11 SHARED_EIFFEL_PROJECT
12
13 CA_SHARED_NAMES
14
15 create
16 make
17
18 feature {NONE} -- Initialization
19
20 make
21 -- Initialization for `Current'.
22 do
23 create settings.make
24 create rules.make
25 -- Adding the rules.
26 rules.extend (create {CA_SELF_ASSIGNMENT_RULE}.make)
27 rules.extend (create {CA_UNUSED_ARGUMENT_RULE}.make)
28 rules.extend (create {CA_NPATH_RULE}.make (settings.preference_manager))
29 rules.extend (create {CA_EMPTY_IF_RULE}.make)
30 rules.extend (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
31 rules.extend (create {CA_CQ_SEPARATION_RULE}.make)
32 rules.extend (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
33 rules.extend (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make) -- Needs type info.
34 rules.extend (create {CA_NESTED_COMPLEXITY_RULE}.make (settings.preference_manager))
35 rules.extend (create {CA_MANY_ARGUMENTS_RULE}.make (settings.preference_manager))
36 rules.extend (create {CA_CREATION_PROC_EXPORTED_RULE}.make)
37 rules.extend (create {CA_VARIABLE_NOT_READ_RULE}.make)
38 rules.extend (create {CA_SEMICOLON_ARGUMENTS_RULE}.make)
39 rules.extend (create {CA_VERY_LONG_ROUTINE_RULE}.make (settings.preference_manager))
40 rules.extend (create {CA_VERY_BIG_CLASS_RULE}.make (settings.preference_manager))
41 rules.extend (create {CA_FEATURE_SECTION_COMMENT_RULE}.make)
42 rules.extend (create {CA_FEATURE_NOT_COMMENTED_RULE}.make)
43 rules.extend (create {CA_BOOLEAN_RESULT_RULE}.make)
44 rules.extend (create {CA_BOOLEAN_COMPARISON_RULE}.make)
45 rules.extend (create {CA_VERY_SHORT_IDENTIFIER_RULE}.make (settings.preference_manager))
46 rules.extend (create {CA_VERY_LONG_IDENTIFIER_RULE}.make (settings.preference_manager))
47 rules.extend (create {CA_MISSING_IS_EQUAL_RULE}.make)
48 rules.extend (create {CA_SIMPLIFIABLE_BOOLEAN_RULE}.make)
49 rules.extend (create {CA_SELF_COMPARISON_RULE}.make)
50 rules.extend (create {CA_TODO_RULE}.make)
51 rules.extend (create {CA_WRONG_LOOP_ITERATION_RULE}.make)
52 rules.extend (create {CA_INSPECT_INSTRUCTIONS_RULE}.make (settings.preference_manager))
53 rules.extend (create {CA_ATTRIBUTE_TO_LOCAL_RULE}.make)
54 rules.extend (create {CA_EMPTY_EFFECTIVE_ROUTINE_RULE}.make)
55 rules.extend (create {CA_IF_ELSE_NOT_EQUAL_RULE}.make)
56 rules.extend (create {CA_SHORT_CIRCUIT_IF_RULE}.make)
57 rules.extend (create {CA_ITERABLE_LOOP_RULE}.make) -- Needs type info.
58 rules.extend (create {CA_COUNT_EQUALS_ZERO_RULE}.make) -- Needs type info.
59 rules.extend (create {CA_DEEPLY_NESTED_IF_RULE}.make (settings.preference_manager))
60 rules.extend (create {CA_UNNEEDED_HELPER_VARIABLE_RULE}.make (settings.preference_manager))
61 rules.extend (create {CA_UNNEEDED_PARENTHESES_RULE}.make)
62
63 settings.initialize_rule_settings (rules)
64
65 create classes_to_analyze.make
66 create rule_violations.make (100)
67 create completed_actions
68 create output_actions
69
70 create ignoredby.make (25)
71 create library_class.make (25)
72 create nonlibrary_class.make (25)
73 end
74
75 feature -- Analysis interface
76
77 add_completed_action (a_action: PROCEDURE [ANY, TUPLE [BOOLEAN]])
78 -- Adds `a_action' to the list of procedures that will be
79 -- called when analysis has completed.
80 do
81 completed_actions.extend (a_action)
82 end
83
84 add_output_action (a_action: PROCEDURE [ANY, TUPLE [READABLE_STRING_GENERAL]])
85 do
86 output_actions.extend (a_action)
87 end
88
89 analyze
90 -- Analyze all the classes that have been added.
91 require
92 not is_running
93 local
94 l_rules_checker: CA_ALL_RULES_CHECKER
95 l_task: CA_RULE_CHECKING_TASK
96 l_rules_to_check: LINKED_LIST [CA_RULE]
97 do
98 is_running := True
99
100 create l_rules_checker.make
101 create l_rules_to_check.make
102 across rules as l_rules loop
103 l_rules.item.clear_violations
104 if is_rule_checkable (l_rules.item) then
105 l_rules_to_check.extend (l_rules.item)
106 -- Here we only prepare standard rules. The rule checking task will iterate again
107 -- through the rules and run the analysis on the enabled rules.
108 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
109 l_std_rule.prepare_checking (l_rules_checker)
110 end
111 end
112 end
113
114 create l_task.make (l_rules_checker, l_rules_to_check, classes_to_analyze, agent analysis_completed)
115 l_task.set_output_actions (output_actions)
116 rota.run_task (l_task)
117 end
118
119 is_rule_checkable (a_rule: CA_RULE): BOOLEAN
120 do
121 Result := a_rule.is_enabled.value
122 and then (system_wide_check or else (not a_rule.is_system_wide))
123 and then is_severity_enabled (a_rule.severity)
124 end
125
126 clear_classes_to_analyze
127 -- Remove all classes that have been added to the list of classes
128 -- to analyze.
129 do
130 classes_to_analyze.wipe_out
131 end
132
133 add_whole_system
134 -- Add all the classes that are part of the current system. Classes of references libraries
135 -- will not be added.
136 local
137 l_groups: LIST [CONF_GROUP]
138 l_cluster: CLUSTER_I
139 do
140 from
141 l_groups := eiffel_universe.groups
142 l_groups.start
143 until
144 l_groups.after
145 loop
146 l_cluster ?= l_groups.item_for_iteration
147 -- Only load top-level clusters, as the others will be loaded recursively afterwards.
148 if l_cluster /= Void and then l_cluster.parent_cluster = Void then
149 add_cluster (l_cluster)
150 end
151 l_groups.forth
152 end
153
154 system_wide_check := True
155 end
156
157 add_cluster (a_cluster: CLUSTER_I)
158 -- Add all classes of cluster `a_cluster'.
159 local
160 l_conf_class: CONF_CLASS
161 l_class_i: CLASS_I
162 do
163 system_wide_check := False
164
165 from
166 a_cluster.classes.start
167 until
168 a_cluster.classes.after
169 loop
170 l_conf_class := a_cluster.classes.item_for_iteration
171 l_class_i := eiffel_universe.class_named (l_conf_class.name, a_cluster)
172 add_class (l_class_i)
173 a_cluster.classes.forth
174 end
175 if a_cluster.sub_clusters /= Void then
176 from
177 a_cluster.sub_clusters.start
178 until
179 a_cluster.sub_clusters.after
180 loop
181 add_cluster (a_cluster.sub_clusters.item_for_iteration)
182 a_cluster.sub_clusters.forth
183 end
184 end
185 end
186
187 add_group (a_group: CONF_GROUP)
188 -- Add all classes of the configuration group `a_group'.
189 require
190 a_group_not_void: a_group /= Void
191 local
192 l_conf_class: CONF_CLASS
193 l_class_i: CLASS_I
194 do
195 from
196 a_group.classes.start
197 until
198 a_group.classes.after
199 loop
200 l_conf_class := a_group.classes.item_for_iteration
201 l_class_i := eiffel_universe.class_named (l_conf_class.name, a_group)
202 add_class (l_class_i)
203 a_group.classes.forth
204 end
205 end
206
207 add_classes (a_classes: ITERABLE [CLASS_I])
208 -- Add the classes `a_classes'.
209 do
210 system_wide_check := False
211
212 across a_classes as l_classes loop
213 add_class (l_classes.item)
214 end
215 end
216
217 add_class (a_class: CLASS_I)
218 -- Adds class `a_class'.
219 local
220 l_class_c: CLASS_C
221 do
222 system_wide_check := False
223
224 if a_class.is_compiled then
225 l_class_c := a_class.compiled_class
226 check l_class_c /= Void end
227 classes_to_analyze.extend (l_class_c)
228
229 extract_indexes (l_class_c)
230 else
231 output_actions.call ([ca_messages.class_skipped (a_class.name)])
232 end
233 end
234
235 feature -- Properties
236
237 is_running: BOOLEAN
238 -- Is code analysis running?
239
240 rules: LINKED_LIST [CA_RULE]
241 -- List of rules that will be used for analysis.
242
243 rule_violations: detachable HASH_TABLE [SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION], CLASS_C]
244 -- All found violations from the last analysis.
245
246 preferences: PREFERENCES
247 -- Code Analysis preferences.
248 do Result := settings.preferences end
249
250 class_list: ITERABLE [CLASS_C]
251 -- List of classes that have been added.
252 do Result := classes_to_analyze end
253
254 feature {NONE} -- Implementation
255
256 csv_file_name: STRING = "last_analysis_result.csv"
257
258 csv_header: STRING = "Severity;Class;Location;Title;Description;Rule ID;Severity Score"
259
260 analysis_completed
261 -- Will be called when the analysis task has finished.
262 local
263 l_csv_writer: CA_CSV_WRITER
264 do
265 create l_csv_writer.make (csv_file_name, csv_header)
266
267 across rules as l_rules loop
268 across l_rules.item.violations as l_v loop
269 -- Check the ignore list.
270 if is_violation_valid (l_v.item) then
271 -- Make sure a list for this class exists in the hash table:
272 rule_violations.put (create {SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION]}.make, l_v.item.affected_class)
273 -- Add the violation.
274 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
275 -- Log it.
276 l_csv_writer.add_line (l_v.item.csv_line)
277 end
278 end
279 end
280
281 l_csv_writer.close_file
282
283 clear_classes_to_analyze
284
285 is_running := False
286 completed_actions.call ([True])
287 completed_actions.wipe_out
288 end
289
290 is_violation_valid (a_viol: CA_RULE_VIOLATION): BOOLEAN
291 -- Is the violation `a_viol' valid under the current settings
292 -- such as the rule ignore list of a class, or the library or
293 -- non-library status of a class?
294 local
295 l_affected_class: CLASS_C
296 l_rule: CA_RULE
297 do
298 l_affected_class := a_viol.affected_class
299 l_rule := a_viol.rule
300
301 Result := True
302
303 if ignoredby.has (l_affected_class)
304 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
305 Result := False
306 end
307
308 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) then
309 Result := False
310 end
311
312 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) then
313 Result := False
314 end
315 end
316
317 settings: CA_SETTINGS
318 -- The settings manager for Code Analysis.
319
320 classes_to_analyze: LINKED_SET [CLASS_C]
321 -- List of classes that shall be analyzed.
322
323 system_wide_check: BOOLEAN
324 -- Shall the whole system be analyzed?
325
326 completed_actions: ACTION_SEQUENCE [TUPLE [BOOLEAN]]
327 -- List of procedures to call when analysis has completed.
328
329 frozen rota: detachable ROTA_S
330 -- Accesses the rota service.
331 local
332 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
333 do
334 create l_service_consumer
335 if l_service_consumer.is_service_available and then l_service_consumer.service.is_interface_usable then
336 Result := l_service_consumer.service
337 end
338 end
339
340 is_severity_enabled (a_severity: CA_RULE_SEVERITY): BOOLEAN
341 do
342 Result := (attached {CA_HINT} a_severity and settings.are_hints_enabled.value)
343 or else (attached {CA_SUGGESTION} a_severity and settings.are_suggestions_enabled.value)
344 or else (attached {CA_WARNING} a_severity and settings.are_warnings_enabled.value)
345 or else (attached {CA_ERROR} a_severity and settings.are_errors_enabled.value)
346 end
347
348 output_actions: ACTION_SEQUENCE [TUPLE [READABLE_STRING_GENERAL]]
349 -- Will be called whenever there is a message to output.
350
351 feature {NONE} -- Class-wide Options (From Indexing Clauses)
352
353 extract_indexes (a_class: CLASS_C)
354 -- Extracts options from the indexing clause of class `a_class'.
355 local
356 l_ast: CLASS_AS
357 l_ignoredby: LINKED_LIST [STRING_32]
358 do
359 create l_ignoredby.make
360 l_ignoredby.compare_objects -- We want to compare the actual strings.
361 -- Reset the class flags.
362 library_class.force (False, a_class)
363 nonlibrary_class.force (False, a_class)
364 l_ast := a_class.ast
365
366 if attached l_ast.internal_top_indexes as l_top then
367 search_indexing_tags (l_top, a_class, l_ignoredby)
368 end
369 if attached l_ast.internal_bottom_indexes as l_bottom then
370 search_indexing_tags (l_bottom, a_class, l_ignoredby)
371 end
372
373 ignoredby.force (l_ignoredby, a_class)
374 end
375
376 search_indexing_tags (a_clause: INDEXING_CLAUSE_AS; a_class: CLASS_C; a_ignoredby: LINKED_LIST [STRING_32])
377 -- Searches `a_clause' for settings relevant to code analysis.
378 local
379 l_item: STRING_32
380 do
381 across a_clause as ic loop
382 if ic.item.tag.name_32.is_equal ("ca_ignoredby") then
383 -- Class wants to ignore certain rules.
384 across ic.item.index_list as l_list loop
385 l_item := l_list.item.string_value_32
386 l_item.prune_all ('%"')
387 a_ignoredby.extend (l_item)
388 end
389 elseif ic.item.tag.name_32.is_equal ("ca_library") then
390 -- Class has information on whether it is a library class.
391 if not ic.item.index_list.is_empty then
392 l_item := ic.item.index_list.first.string_value_32
393 l_item.to_lower
394 l_item.prune_all ('%"')
395 if l_item.is_equal ("true") then
396 library_class.force (True, a_class)
397 elseif l_item.is_equal ("false") then
398 nonlibrary_class.force (True, a_class)
399 end
400 end
401 end
402 end
403 end
404
405 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
406 -- Maps classes to lists of rules (rule IDs) the class wants to be ignored by.
407
408 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
409 -- Stores classes that are marked as library or non-library classes.
410
411 invariant
412 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
413
414 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23