/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 94740 - (show annotations)
Fri Mar 28 09:42:08 2014 UTC (5 years, 9 months ago) by jasonw
File size: 12840 byte(s)
<<Merged from trunk#94739.>>
1 note
2 description: "THE Code Analyzer."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit
11 SHARED_EIFFEL_PROJECT
12
13 CA_SHARED_NAMES
14
15 create
16 make
17
18 feature {NONE} -- Initialization
19
20 make
21 -- Initialization for `Current'.
22 do
23 create settings.make
24 create rules.make
25 -- Adding the rules.
26 rules.extend (create {CA_SELF_ASSIGNMENT_RULE}.make)
27 rules.extend (create {CA_UNUSED_ARGUMENT_RULE}.make)
28 rules.extend (create {CA_NPATH_RULE}.make (settings.preference_manager))
29 rules.extend (create {CA_EMPTY_IF_RULE}.make)
30 rules.extend (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
31 rules.extend (create {CA_CQ_SEPARATION_RULE}.make)
32 rules.extend (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
33 rules.extend (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make) -- Needs type info.
34 rules.extend (create {CA_NESTED_COMPLEXITY_RULE}.make (settings.preference_manager))
35 rules.extend (create {CA_MANY_ARGUMENTS_RULE}.make (settings.preference_manager))
36 rules.extend (create {CA_CREATION_PROC_EXPORTED_RULE}.make)
37 rules.extend (create {CA_VARIABLE_NOT_READ_RULE}.make)
38 rules.extend (create {CA_SEMICOLON_ARGUMENTS_RULE}.make)
39 rules.extend (create {CA_VERY_LONG_ROUTINE_RULE}.make (settings.preference_manager))
40 rules.extend (create {CA_VERY_BIG_CLASS_RULE}.make (settings.preference_manager))
41 rules.extend (create {CA_FEATURE_SECTION_COMMENT_RULE}.make)
42 rules.extend (create {CA_FEATURE_NOT_COMMENTED_RULE}.make)
43 rules.extend (create {CA_BOOLEAN_RESULT_RULE}.make)
44 rules.extend (create {CA_BOOLEAN_COMPARISON_RULE}.make)
45 rules.extend (create {CA_VERY_SHORT_IDENTIFIER_RULE}.make (settings.preference_manager))
46 rules.extend (create {CA_VERY_LONG_IDENTIFIER_RULE}.make (settings.preference_manager))
47 rules.extend (create {CA_MISSING_IS_EQUAL_RULE}.make)
48 rules.extend (create {CA_SIMPLIFIABLE_BOOLEAN_RULE}.make)
49 rules.extend (create {CA_SELF_COMPARISON_RULE}.make)
50 rules.extend (create {CA_TODO_RULE}.make)
51 rules.extend (create {CA_WRONG_LOOP_ITERATION_RULE}.make)
52 rules.extend (create {CA_INSPECT_INSTRUCTIONS_RULE}.make (settings.preference_manager))
53 rules.extend (create {CA_ATTRIBUTE_TO_LOCAL_RULE}.make)
54 rules.extend (create {CA_EMPTY_EFFECTIVE_ROUTINE_RULE}.make)
55 rules.extend (create {CA_IF_ELSE_NOT_EQUAL_RULE}.make)
56 rules.extend (create {CA_SHORT_CIRCUIT_IF_RULE}.make)
57 rules.extend (create {CA_ITERABLE_LOOP_RULE}.make) -- Needs type info.
58 rules.extend (create {CA_COUNT_EQUALS_ZERO_RULE}.make) -- Needs type info.
59 rules.extend (create {CA_DEEPLY_NESTED_IF_RULE}.make (settings.preference_manager))
60 rules.extend (create {CA_UNNEEDED_HELPER_VARIABLE_RULE}.make (settings.preference_manager))
61 rules.extend (create {CA_UNNEEDED_PARENTHESES_RULE}.make)
62
63 settings.initialize_rule_settings (rules)
64
65 create classes_to_analyze.make
66 create rule_violations.make (100)
67 create completed_actions
68 create output_actions
69
70 create ignoredby.make (25)
71 create library_class.make (25)
72 create nonlibrary_class.make (25)
73 end
74
75 feature -- Analysis interface
76
77 add_completed_action (a_action: attached PROCEDURE [ANY, TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]])
78 -- Adds `a_action' to the list of procedures that will be
79 -- called when analysis has completed.
80 do
81 completed_actions.extend (a_action)
82 end
83
84 add_output_action (a_action: attached PROCEDURE [ANY, TUPLE [READABLE_STRING_GENERAL]])
85 -- Adds `a_action' to the procedures that are called for outputting status. The final results
86 -- (rule violations) are not given to these procedures.
87 do
88 output_actions.extend (a_action)
89 end
90
91 analyze
92 -- Analyze all the classes that have been added.
93 require
94 not is_running
95 local
96 l_rules_checker: CA_ALL_RULES_CHECKER
97 l_task: CA_RULE_CHECKING_TASK
98 l_rules_to_check: LINKED_LIST [CA_RULE]
99 do
100 is_running := True
101
102 create l_rules_checker.make
103 create l_rules_to_check.make
104 across rules as l_rules loop
105 l_rules.item.clear_violations
106 if is_rule_checkable (l_rules.item) then
107 l_rules_to_check.extend (l_rules.item)
108 -- Here we only prepare standard rules. The rule checking task will iterate again
109 -- through the rules and run the analysis on the enabled rules.
110 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
111 l_std_rule.prepare_checking (l_rules_checker)
112 end
113 end
114 end
115
116 create l_task.make (l_rules_checker, l_rules_to_check, classes_to_analyze, agent analysis_completed)
117 l_task.set_output_actions (output_actions)
118 rota.run_task (l_task)
119 end
120
121 is_rule_checkable (a_rule: attached CA_RULE): BOOLEAN
122 -- Will `a_rule' be checked based on the current preferences and based on the current
123 -- checking scope?
124 do
125 Result := a_rule.is_enabled.value
126 and then (system_wide_check or else (not a_rule.is_system_wide))
127 and then is_severity_enabled (a_rule.severity)
128 end
129
130 clear_classes_to_analyze
131 -- Removes all classes that have been added to the list of classes
132 -- to analyze.
133 do
134 classes_to_analyze.wipe_out
135 end
136
137 add_whole_system
138 -- Adds all the classes that are part of the current system. Classes of referenced libraries
139 -- will not be added.
140 local
141 l_cluster: CLUSTER_I
142 do
143 across
144 eiffel_universe.groups as l_groups
145 loop
146 l_cluster ?= l_groups.item
147 -- Only load top-level clusters, as the others will be loaded recursively afterwards.
148 if l_cluster /= Void and then l_cluster.parent_cluster = Void then
149 add_cluster (l_cluster)
150 end
151 end
152
153 system_wide_check := True
154 end
155
156 add_cluster (a_cluster: attached CLUSTER_I)
157 -- Add all classes of cluster `a_cluster'.
158 do
159 system_wide_check := False
160
161 if a_cluster.classes /= Void then
162 across a_cluster.classes as ic loop
163 add_class (ic.item)
164 end
165 end
166
167 if a_cluster.sub_clusters /= Void then
168 across a_cluster.sub_clusters as ic loop
169 add_cluster (ic.item)
170 end
171 end
172 end
173
174 add_group (a_group: attached CONF_GROUP)
175 -- Add all classes of the configuration group `a_group'.
176 require
177 a_group_not_void: a_group /= Void
178 do
179 if a_group.classes /= Void then
180 across a_group.classes as ic loop
181 add_class (ic.item)
182 end
183 end
184 end
185
186 add_classes (a_classes: attached ITERABLE [attached CONF_CLASS])
187 -- Add the classes `a_classes'.
188 do
189 system_wide_check := False
190
191 across a_classes as l_classes loop
192 add_class (l_classes.item)
193 end
194 end
195
196 add_class (a_class: attached CONF_CLASS)
197 -- Adds class `a_class'.
198 local
199 l_class_c: CLASS_C
200 do
201 system_wide_check := False
202
203 if attached {EIFFEL_CLASS_I} a_class as l_eiffel_class
204 and then attached l_eiffel_class.compiled_class as l_compiled
205 then
206 classes_to_analyze.extend (l_compiled)
207
208 extract_indexes (l_compiled)
209 else
210 output_actions.call ([ca_messages.class_skipped (a_class.name)])
211 end
212 end
213
214 feature -- Properties
215
216 is_running: BOOLEAN
217 -- Is code analysis running?
218
219 rules: LINKED_LIST [CA_RULE]
220 -- List of rules that will be used for analysis.
221
222 rule_violations: detachable HASH_TABLE [SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION], CLASS_C]
223 -- All found violations from the last analysis.
224
225 settings: CA_SETTINGS
226 -- The settings manager for Code Analysis.
227
228 preferences: PREFERENCES
229 -- Code Analysis preferences.
230 do Result := settings.preferences end
231
232 class_list: ITERABLE [CLASS_C]
233 -- List of classes that have been added.
234 do Result := classes_to_analyze end
235
236 feature {NONE} -- Implementation
237
238 csv_file_name: STRING = "last_analysis_result.csv"
239
240 csv_header: STRING = "Severity;Class;Location;Title;Description;Rule ID;Severity Score"
241
242 analysis_completed (a_exceptions: detachable ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]])
243 -- Will be called when the analysis task has finished. `a_exceptions'
244 -- contains a list of exception that occurred during analysis.
245 local
246 l_csv_writer: CA_CSV_WRITER
247 do
248 create l_csv_writer.make (csv_file_name, csv_header)
249
250 across rules as l_rules loop
251 across l_rules.item.violations as l_v loop
252 -- Check the ignore list.
253 if is_violation_valid (l_v.item) then
254 -- Make sure a list for this class exists in the hash table:
255 rule_violations.put (create {SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION]}.make, l_v.item.affected_class)
256 -- Add the violation.
257 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
258 -- Log it.
259 l_csv_writer.add_line (l_v.item.csv_line)
260 end
261 end
262 end
263
264 l_csv_writer.close_file
265
266 clear_classes_to_analyze
267
268 is_running := False
269 completed_actions.call ([a_exceptions])
270 completed_actions.wipe_out
271 end
272
273 is_violation_valid (a_viol: attached CA_RULE_VIOLATION): BOOLEAN
274 -- Is the violation `a_viol' valid under the current settings
275 -- such as the rule ignore list of a class, or the library or
276 -- non-library status of a class?
277 local
278 l_affected_class: CLASS_C
279 l_rule: CA_RULE
280 do
281 l_affected_class := a_viol.affected_class
282 l_rule := a_viol.rule
283
284 Result := True
285
286 if ignoredby.has (l_affected_class)
287 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
288 Result := False
289 end
290
291 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) then
292 Result := False
293 end
294
295 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) then
296 Result := False
297 end
298 end
299
300 classes_to_analyze: LINKED_SET [CLASS_C]
301 -- List of classes that shall be analyzed.
302
303 system_wide_check: BOOLEAN
304 -- Shall the whole system be analyzed?
305
306 completed_actions: ACTION_SEQUENCE [TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]]
307 -- List of procedures to call when analysis has completed.
308
309 frozen rota: detachable ROTA_S
310 -- Accesses the rota service.
311 local
312 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
313 do
314 create l_service_consumer
315 if attached l_service_consumer.service as l_service and then l_service.is_interface_usable then
316 Result := l_service
317 end
318 end
319
320 is_severity_enabled (a_severity: attached CA_RULE_SEVERITY): BOOLEAN
321 do
322 Result := (attached {CA_HINT} a_severity and settings.are_hints_enabled.value)
323 or else (attached {CA_SUGGESTION} a_severity and settings.are_suggestions_enabled.value)
324 or else (attached {CA_WARNING} a_severity and settings.are_warnings_enabled.value)
325 or else (attached {CA_ERROR} a_severity and settings.are_errors_enabled.value)
326 end
327
328 output_actions: ACTION_SEQUENCE [TUPLE [READABLE_STRING_GENERAL]]
329 -- Will be called whenever there is a message to output.
330
331 feature {NONE} -- Class-wide Options (From Indexing Clauses)
332
333 extract_indexes (a_class: attached CLASS_C)
334 -- Extracts options from the indexing clause of class `a_class'.
335 local
336 l_ast: CLASS_AS
337 l_ignoredby: LINKED_LIST [STRING_32]
338 do
339 create l_ignoredby.make
340 l_ignoredby.compare_objects -- We want to compare the actual strings.
341 -- Reset the class flags.
342 library_class.force (False, a_class)
343 nonlibrary_class.force (False, a_class)
344 l_ast := a_class.ast
345
346 if attached l_ast.internal_top_indexes as l_top then
347 search_indexing_tags (l_top, a_class, l_ignoredby)
348 end
349 if attached l_ast.internal_bottom_indexes as l_bottom then
350 search_indexing_tags (l_bottom, a_class, l_ignoredby)
351 end
352
353 ignoredby.force (l_ignoredby, a_class)
354 end
355
356 search_indexing_tags (a_clause: attached INDEXING_CLAUSE_AS; a_class: attached CLASS_C; a_ignoredby: attached LINKED_LIST [STRING_32])
357 -- Searches `a_clause' for settings relevant to code analysis.
358 local
359 l_item: STRING_32
360 do
361 across a_clause as ic loop
362 if ic.item.tag.name_32.is_equal ("ca_ignoredby") then
363 -- Class wants to ignore certain rules.
364 across ic.item.index_list as l_list loop
365 l_item := l_list.item.string_value_32
366 l_item.prune_all ('%"')
367 a_ignoredby.extend (l_item)
368 end
369 elseif ic.item.tag.name_32.is_equal ("ca_library") then
370 -- Class has information on whether it is a library class.
371 if not ic.item.index_list.is_empty then
372 l_item := ic.item.index_list.first.string_value_32
373 l_item.to_lower
374 l_item.prune_all ('%"')
375 if l_item.is_equal ("true") then
376 library_class.force (True, a_class)
377 elseif l_item.is_equal ("false") then
378 nonlibrary_class.force (True, a_class)
379 end
380 end
381 end
382 end
383 end
384
385 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
386 -- Maps classes to lists of rules (rule IDs) the class wants to be ignored by.
387
388 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
389 -- Stores classes that are marked as library or non-library classes.
390
391 invariant
392 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
393
394 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23