/[eiffelstudio]/branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e
ViewVC logotype

Contents of /branches/eth/eve/Src/framework/code_analysis/ca_code_analyzer.e

Parent Directory Parent Directory | Revision Log Revision Log


Revision 94861 - (show annotations)
Wed Apr 16 16:15:49 2014 UTC (5 years, 9 months ago) by apaolo
File size: 13563 byte(s)
Adding new rules about naming conventions and unnecessary unary operators.
1 note
2 description: "THE Code Analyzer."
3 author: "Stefan Zurfluh"
4 date: "$Date$"
5 revision: "$Revision$"
6
7 class
8 CA_CODE_ANALYZER
9
10 inherit
11 SHARED_EIFFEL_PROJECT
12
13 CA_SHARED_NAMES
14
15 create
16 make
17
18 feature {NONE} -- Initialization
19
20 make
21 -- Initialization for `Current'.
22 do
23 create settings.make
24 create rules.make
25 -- Adding the rules.
26 rules.extend (create {CA_SELF_ASSIGNMENT_RULE}.make)
27 rules.extend (create {CA_UNUSED_ARGUMENT_RULE}.make)
28 rules.extend (create {CA_NPATH_RULE}.make (settings.preference_manager))
29 rules.extend (create {CA_EMPTY_IF_RULE}.make)
30 rules.extend (create {CA_FEATURE_NEVER_CALLED_RULE}.make)
31 rules.extend (create {CA_CQ_SEPARATION_RULE}.make)
32 rules.extend (create {CA_UNNEEDED_OT_LOCAL_RULE}.make)
33 rules.extend (create {CA_UNNEEDED_OBJECT_TEST_RULE}.make) -- Needs type info.
34 rules.extend (create {CA_NESTED_COMPLEXITY_RULE}.make (settings.preference_manager))
35 rules.extend (create {CA_MANY_ARGUMENTS_RULE}.make (settings.preference_manager))
36 rules.extend (create {CA_CREATION_PROC_EXPORTED_RULE}.make)
37 rules.extend (create {CA_VARIABLE_NOT_READ_RULE}.make)
38 rules.extend (create {CA_SEMICOLON_ARGUMENTS_RULE}.make)
39 rules.extend (create {CA_VERY_LONG_ROUTINE_RULE}.make (settings.preference_manager))
40 rules.extend (create {CA_VERY_BIG_CLASS_RULE}.make (settings.preference_manager))
41 rules.extend (create {CA_FEATURE_SECTION_COMMENT_RULE}.make)
42 rules.extend (create {CA_FEATURE_NOT_COMMENTED_RULE}.make)
43 rules.extend (create {CA_BOOLEAN_RESULT_RULE}.make)
44 rules.extend (create {CA_BOOLEAN_COMPARISON_RULE}.make)
45 rules.extend (create {CA_VERY_SHORT_IDENTIFIER_RULE}.make (settings.preference_manager))
46 rules.extend (create {CA_VERY_LONG_IDENTIFIER_RULE}.make (settings.preference_manager))
47 rules.extend (create {CA_MISSING_IS_EQUAL_RULE}.make)
48 rules.extend (create {CA_SIMPLIFIABLE_BOOLEAN_RULE}.make)
49 rules.extend (create {CA_SELF_COMPARISON_RULE}.make)
50 rules.extend (create {CA_TODO_RULE}.make)
51 rules.extend (create {CA_WRONG_LOOP_ITERATION_RULE}.make)
52 rules.extend (create {CA_INSPECT_INSTRUCTIONS_RULE}.make (settings.preference_manager))
53 rules.extend (create {CA_ATTRIBUTE_TO_LOCAL_RULE}.make)
54 rules.extend (create {CA_EMPTY_EFFECTIVE_ROUTINE_RULE}.make)
55 rules.extend (create {CA_IF_ELSE_NOT_EQUAL_RULE}.make)
56 rules.extend (create {CA_SHORT_CIRCUIT_IF_RULE}.make)
57 rules.extend (create {CA_ITERABLE_LOOP_RULE}.make) -- Needs type info.
58 rules.extend (create {CA_COUNT_EQUALS_ZERO_RULE}.make) -- Needs type info.
59 rules.extend (create {CA_DEEPLY_NESTED_IF_RULE}.make (settings.preference_manager))
60 rules.extend (create {CA_UNNEEDED_HELPER_VARIABLE_RULE}.make (settings.preference_manager))
61 rules.extend (create {CA_UNNEEDED_PARENTHESES_RULE}.make)
62 rules.extend (create {CA_CLASS_NAMING_CONVENTION_RULE}.make)
63 rules.extend (create {CA_FEATURE_NAMING_CONVENTION_RULE}.make)
64 rules.extend (create {CA_VARIABLE_NAMING_CONVENTION_RULE}.make)
65 rules.extend (create {CA_ARGUMENT_NAMING_CONVENTION_RULE}.make)
66 rules.extend (create {CA_UNNECESSARY_SIGN_OPERAND}.make)
67
68 settings.initialize_rule_settings (rules)
69
70 create classes_to_analyze.make
71 create rule_violations.make (100)
72 create completed_actions
73 create output_actions
74
75 create ignoredby.make (25)
76 create library_class.make (25)
77 create nonlibrary_class.make (25)
78 end
79
80 feature -- Analysis interface
81
82 add_completed_action (a_action: attached PROCEDURE [ANY, TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]])
83 -- Adds `a_action' to the list of procedures that will be
84 -- called when analysis has completed.
85 do
86 completed_actions.extend (a_action)
87 end
88
89 add_output_action (a_action: attached PROCEDURE [ANY, TUPLE [READABLE_STRING_GENERAL]])
90 -- Adds `a_action' to the procedures that are called for outputting status. The final results
91 -- (rule violations) are not given to these procedures.
92 do
93 output_actions.extend (a_action)
94 end
95
96 analyze
97 -- Analyze all the classes that have been added.
98 require
99 not is_running
100 local
101 l_rules_checker: CA_ALL_RULES_CHECKER
102 l_task: CA_RULE_CHECKING_TASK
103 l_rules_to_check: LINKED_LIST [CA_RULE]
104 do
105 is_running := True
106
107 create l_rules_checker.make
108 create l_rules_to_check.make
109 across rules as l_rules loop
110 l_rules.item.clear_violations
111 if is_rule_checkable (l_rules.item) then
112 l_rules_to_check.extend (l_rules.item)
113 -- Here we only prepare standard rules. The rule checking task will iterate again
114 -- through the rules and run the analysis on the enabled rules.
115 if attached {CA_STANDARD_RULE} l_rules.item as l_std_rule then
116 l_std_rule.prepare_checking (l_rules_checker)
117 end
118 end
119 end
120
121 create l_task.make (l_rules_checker, l_rules_to_check, classes_to_analyze, agent analysis_completed)
122 l_task.set_output_actions (output_actions)
123 rota.run_task (l_task)
124 end
125
126 is_rule_checkable (a_rule: attached CA_RULE): BOOLEAN
127 -- Will `a_rule' be checked based on the current preferences and based on the current
128 -- checking scope?
129 do
130 Result := a_rule.is_enabled.value
131 and then (system_wide_check or else (not a_rule.is_system_wide))
132 and then is_severity_enabled (a_rule.severity)
133 end
134
135 clear_classes_to_analyze
136 -- Removes all classes that have been added to the list of classes
137 -- to analyze.
138 do
139 classes_to_analyze.wipe_out
140 end
141
142 add_whole_system
143 -- Adds all the classes that are part of the current system. Classes of referenced libraries
144 -- will not be added.
145 local
146 l_cluster: CLUSTER_I
147 do
148 across
149 eiffel_universe.groups as l_groups
150 loop
151 l_cluster ?= l_groups.item
152 -- Only load top-level clusters, as the others will be loaded recursively afterwards.
153 if l_cluster /= Void and then l_cluster.parent_cluster = Void then
154 add_cluster (l_cluster)
155 end
156 end
157
158 system_wide_check := True
159 end
160
161 add_cluster (a_cluster: attached CLUSTER_I)
162 -- Add all classes of cluster `a_cluster'.
163 do
164 system_wide_check := False
165
166 if a_cluster.classes /= Void then
167 across a_cluster.classes as ic loop
168 add_class (ic.item)
169 end
170 end
171
172 if a_cluster.sub_clusters /= Void then
173 across a_cluster.sub_clusters as ic loop
174 add_cluster (ic.item)
175 end
176 end
177 end
178
179 add_group (a_group: attached CONF_GROUP)
180 -- Add all classes of the configuration group `a_group'.
181 require
182 a_group_not_void: a_group /= Void
183 do
184 if a_group.classes /= Void then
185 across a_group.classes as ic loop
186 add_class (ic.item)
187 end
188 end
189 end
190
191 add_classes (a_classes: attached ITERABLE [attached CONF_CLASS])
192 -- Add the classes `a_classes'.
193 do
194 system_wide_check := False
195
196 across a_classes as l_classes loop
197 add_class (l_classes.item)
198 end
199 end
200
201 add_class (a_class: attached CONF_CLASS)
202 -- Adds class `a_class'.
203 local
204 l_class_c: CLASS_C
205 do
206 system_wide_check := False
207
208 if attached {EIFFEL_CLASS_I} a_class as l_eiffel_class
209 and then attached l_eiffel_class.compiled_class as l_compiled
210 then
211 classes_to_analyze.extend (l_compiled)
212
213 extract_indexes (l_compiled)
214 else
215 output_actions.call ([ca_messages.class_skipped (a_class.name)])
216 end
217 end
218
219 feature -- Properties
220
221 is_running: BOOLEAN
222 -- Is code analysis running?
223
224 rules: LINKED_LIST [CA_RULE]
225 -- List of rules that will be used for analysis.
226
227 rule_violations: detachable HASH_TABLE [SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION], CLASS_C]
228 -- All found violations from the last analysis.
229
230 settings: CA_SETTINGS
231 -- The settings manager for Code Analysis.
232
233 preferences: PREFERENCES
234 -- Code Analysis preferences.
235 do Result := settings.preferences end
236
237 class_list: ITERABLE [CLASS_C]
238 -- List of classes that have been added.
239 do Result := classes_to_analyze end
240
241 feature {NONE} -- Implementation
242
243 csv_file_name: STRING = "last_analysis_result.csv"
244
245 csv_header: STRING = "Severity;Class;Location;Title;Description;Rule ID;Severity Score"
246
247 analysis_completed (a_exceptions: detachable ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]])
248 -- Will be called when the analysis task has finished. `a_exceptions'
249 -- contains a list of exception that occurred during analysis.
250 local
251 l_csv_writer: CA_CSV_WRITER
252 do
253 create l_csv_writer.make (csv_file_name, csv_header)
254
255 across rules as l_rules loop
256 across l_rules.item.violations as l_v loop
257 -- Check the ignore list.
258 if is_violation_valid (l_v.item) then
259 -- Make sure a list for this class exists in the hash table:
260 rule_violations.put (create {SORTED_TWO_WAY_LIST [CA_RULE_VIOLATION]}.make, l_v.item.affected_class)
261 -- Add the violation.
262 rule_violations.at (l_v.item.affected_class).extend (l_v.item)
263 -- Log it.
264 l_csv_writer.add_line (l_v.item.csv_line)
265 end
266 end
267 end
268
269 l_csv_writer.close_file
270
271 clear_classes_to_analyze
272
273 is_running := False
274 completed_actions.call ([a_exceptions])
275 completed_actions.wipe_out
276 end
277
278 is_violation_valid (a_viol: attached CA_RULE_VIOLATION): BOOLEAN
279 -- Is the violation `a_viol' valid under the current settings
280 -- such as the rule ignore list of a class, or the library or
281 -- non-library status of a class?
282 local
283 l_affected_class: CLASS_C
284 l_rule: CA_RULE
285 do
286 l_affected_class := a_viol.affected_class
287 l_rule := a_viol.rule
288
289 Result := True
290
291 if ignoredby.has (l_affected_class)
292 and then (ignoredby.at (l_affected_class)).has (l_rule.id) then
293 Result := False
294 end
295
296 if (not l_rule.checks_library_classes) and then library_class.at (l_affected_class) then
297 Result := False
298 end
299
300 if (not l_rule.checks_nonlibrary_classes) and then nonlibrary_class.at (l_affected_class) then
301 Result := False
302 end
303 end
304
305 classes_to_analyze: LINKED_SET [CLASS_C]
306 -- List of classes that shall be analyzed.
307
308 system_wide_check: BOOLEAN
309 -- Shall the whole system be analyzed?
310
311 completed_actions: ACTION_SEQUENCE [TUPLE [ITERABLE [TUPLE [detachable EXCEPTION, CLASS_C]]]]
312 -- List of procedures to call when analysis has completed.
313
314 frozen rota: detachable ROTA_S
315 -- Accesses the rota service.
316 local
317 l_service_consumer: SERVICE_CONSUMER [ROTA_S]
318 do
319 create l_service_consumer
320 if attached l_service_consumer.service as l_service and then l_service.is_interface_usable then
321 Result := l_service
322 end
323 end
324
325 is_severity_enabled (a_severity: attached CA_RULE_SEVERITY): BOOLEAN
326 do
327 Result := (attached {CA_HINT} a_severity and settings.are_hints_enabled.value)
328 or else (attached {CA_SUGGESTION} a_severity and settings.are_suggestions_enabled.value)
329 or else (attached {CA_WARNING} a_severity and settings.are_warnings_enabled.value)
330 or else (attached {CA_ERROR} a_severity and settings.are_errors_enabled.value)
331 end
332
333 output_actions: ACTION_SEQUENCE [TUPLE [READABLE_STRING_GENERAL]]
334 -- Will be called whenever there is a message to output.
335
336 feature {NONE} -- Class-wide Options (From Indexing Clauses)
337
338 extract_indexes (a_class: attached CLASS_C)
339 -- Extracts options from the indexing clause of class `a_class'.
340 local
341 l_ast: CLASS_AS
342 l_ignoredby: LINKED_LIST [STRING_32]
343 do
344 create l_ignoredby.make
345 l_ignoredby.compare_objects -- We want to compare the actual strings.
346 -- Reset the class flags.
347 library_class.force (False, a_class)
348 nonlibrary_class.force (False, a_class)
349 l_ast := a_class.ast
350
351 if attached l_ast.internal_top_indexes as l_top then
352 search_indexing_tags (l_top, a_class, l_ignoredby)
353 end
354 if attached l_ast.internal_bottom_indexes as l_bottom then
355 search_indexing_tags (l_bottom, a_class, l_ignoredby)
356 end
357
358 ignoredby.force (l_ignoredby, a_class)
359 end
360
361 search_indexing_tags (a_clause: attached INDEXING_CLAUSE_AS; a_class: attached CLASS_C; a_ignoredby: attached LINKED_LIST [STRING_32])
362 -- Searches `a_clause' for settings relevant to code analysis.
363 local
364 l_item: STRING_32
365 do
366 across a_clause as ic loop
367 if ic.item.tag.name_32.is_equal ("ca_ignoredby") then
368 -- Class wants to ignore certain rules.
369 across ic.item.index_list as l_list loop
370 l_item := l_list.item.string_value_32
371 l_item.prune_all ('%"')
372 a_ignoredby.extend (l_item)
373 end
374 elseif ic.item.tag.name_32.is_equal ("ca_library") then
375 -- Class has information on whether it is a library class.
376 if not ic.item.index_list.is_empty then
377 l_item := ic.item.index_list.first.string_value_32
378 l_item.to_lower
379 l_item.prune_all ('%"')
380 if l_item.is_equal ("true") then
381 library_class.force (True, a_class)
382 elseif l_item.is_equal ("false") then
383 nonlibrary_class.force (True, a_class)
384 end
385 end
386 end
387 end
388 end
389
390 ignoredby: HASH_TABLE [LINKED_LIST [STRING_32], CLASS_C]
391 -- Maps classes to lists of rules (rule IDs) the class wants to be ignored by.
392
393 library_class, nonlibrary_class: HASH_TABLE [BOOLEAN, CLASS_C]
394 -- Stores classes that are marked as library or non-library classes.
395
396 invariant
397 -- law_of_non_contradiction: one class must not be both a library_class and a nonlibrary_class
398
399 end

Properties

Name Value
svn:eol-style native
svn:keywords Author Date ID Revision

  ViewVC Help
Powered by ViewVC 1.1.23